Adding metadata

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 32153a780a8c..5fb18b806050 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1 +1,2 @@
 DIST statsmodels-0.14.4.tar.gz 20354802 BLAKE2B c721c5b2e7b22ad1be10099627230f7344f966a335f37757dc6bb622fedcb1e84a7d708ee25bfdde64357394e059567e41dad19fc5b1daeb3d5ee29e52a3b2af SHA512 db3bd19b8b47af453ad6fbd24449a621895e4237bbc8b7813810306748c32a3fbf005387a0e1e8db550c9c4a59666bdd50aeb49e24f0ecb86619bc90f166f5f9
+DIST statsmodels-0.14.5.tar.gz 20525016 BLAKE2B ea0a76aaecfb75fe21bcd6c6df625a86745dc93d568f35fa9d8d230f216487ed311706810245ce16a86dc9cc8e465c4fd6d09f1406899838ff82b80d1d1ff310 SHA512 b36763d2ea3a1db2181838cc05834e96c9914789155b4723ee260f94a6f481fd8ea5c07294e375efd783b06d28cf9b71385c00b94ed0271189da551f562948f3
diff --git a/dev-python/statsmodels/statsmodels-0.14.5.ebuild b/dev-python/statsmodels/statsmodels-0.14.5.ebuild
new file mode 100644
index 000000000000..807a7d929857
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.14.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="
+	https://www.statsmodels.org/stable/index.html
+	https://github.com/statsmodels/statsmodels/
+	https://pypi.org/project/statsmodels/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~amd64-linux"
+IUSE="examples"
+
+# NB: upstream requires building with numpy-2 but supports 1.x
+# at runtime
+DEPEND="
+	>=dev-python/numpy-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.4[${PYTHON_USEDEP}]
+	>=dev-python/patsy-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter-client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest statsmodels
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}