Updating liguros repo

6 files changed, 310 insertions, 0 deletions

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
new file mode 100644
index 000000000000..7fcf0bc04fbb
--- /dev/null
+++ b/dev-python/statsmodels/Manifest
@@ -0,0 +1,2 @@
+DIST statsmodels-0.10.2.tar.gz 14065612 BLAKE2B 0df1268de5e4108b3cc541df87a5b9d2321bd3062d4daf1cc1aa62ab08ee777bace2f10bdfb51f088a66f15287c62cf851b3f43efa7eb1227e71c06632e80d55 SHA512 bd1c0784b0b17a3ca69fef5848f5eea8dcf76b1943599a5e5c285e45b7fcc7e44c0e388f007913d420ff6f3cb66a653d1c43e6e8addef534ff5572fa69ffb54a
+DIST statsmodels-0.11.1.tar.gz 15381516 BLAKE2B a40cf9138edd8a9a6707a550d9885e0610f9bc666fcd73a60bd11ade6dcfa806ecd912a725cf2a13902e92f31af2c3e82f244280f70586bb3359dc8fc2842508 SHA512 54afe55a23b431154c159f44d284aa093f3368988f0695c0f3fbb206046cdfb171ab2ba51ce94285d567b8536141f93a1ef404b5f7222f1e61264baf0541926d
diff --git a/dev-python/statsmodels/files/statsmodels-0.11.1-tests.patch b/dev-python/statsmodels/files/statsmodels-0.11.1-tests.patch
new file mode 100644
index 000000000000..9a1a258d0779
--- /dev/null
+++ b/dev-python/statsmodels/files/statsmodels-0.11.1-tests.patch
@@ -0,0 +1,35 @@
+diff -ur statsmodels-0.11.1.orig/statsmodels/base/tests/test_penalized.py statsmodels-0.11.1/statsmodels/base/tests/test_penalized.py
+--- statsmodels-0.11.1.orig/statsmodels/base/tests/test_penalized.py	2020-04-28 22:02:47.150938650 -0700
++++ statsmodels-0.11.1/statsmodels/base/tests/test_penalized.py	2020-04-28 22:03:24.468704937 -0700
+@@ -73,6 +73,7 @@
+         y = np.random.poisson(mu)
+         return y
+ 
++    @pytest.mark.skip("Broken on all impls")
+     def test_params_table(self):
+         res1 = self.res1
+         res2 = self.res2
+@@ -380,9 +381,6 @@
+         bse = np.array([0.028126650444581985, 0.033099984564283147,
+                         0.033184585514904545, 0.034282504130503301])
+         assert_allclose(res2.params[:self.k_nonzero], params, atol=1e-5)
+-        assert_allclose(res2.bse[:self.k_nonzero], bse, rtol=5e-6)
+-        assert_allclose(res1.params[:self.k_nonzero], params, atol=1e-5)
+-        assert_allclose(res1.bse[:self.k_nonzero], bse, rtol=5e-6)
+ 
+ 
+ # the following classes are copies of Poisson with model adjustments
+Only in statsmodels-0.11.1/statsmodels/base/tests: test_penalized.py.orig
+diff -ur statsmodels-0.11.1.orig/statsmodels/tsa/statespace/tests/test_structural.py statsmodels-0.11.1/statsmodels/tsa/statespace/tests/test_structural.py
+--- statsmodels-0.11.1.orig/statsmodels/tsa/statespace/tests/test_structural.py	2020-04-28 22:02:47.207938293 -0700
++++ statsmodels-0.11.1/statsmodels/tsa/statespace/tests/test_structural.py	2020-04-28 22:04:02.871464429 -0700
+@@ -243,7 +243,7 @@
+     run_ucm('rtrend_ar1', use_exact_diffuse=True)
+ 
+ 
+-@pytest.mark.slow
++@pytest.mark.skip("Fails")
+ def test_lltrend_cycle_seasonal_reg_ar1(close_figures):
+     run_ucm('lltrend_cycle_seasonal_reg_ar1_approx_diffuse')
+     run_ucm('lltrend_cycle_seasonal_reg_ar1', use_exact_diffuse=True)
+Only in statsmodels-0.11.1/statsmodels/tsa/statespace/tests: .test_structural.py.un~
diff --git a/dev-python/statsmodels/metadata.xml b/dev-python/statsmodels/metadata.xml
new file mode 100644
index 000000000000..ce9fffb67345
--- /dev/null
+++ b/dev-python/statsmodels/metadata.xml
@@ -0,0 +1,35 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <maintainer type="person">
+    <email>chr@chymera.eu</email>
+    <name>Horea Christian</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <longdescription lang="en">
+    statsmodels is a Python module that allows users to explore data,
+    estimate statistical models, and perform statistical tests. An
+    extensive list of descriptive statistics, statistical tests,
+    plotting functions, and result statistics are available for
+    different types of data and each estimator. Researchers across
+    fields may find that statsmodels fully meets their needs for
+    statistical computing and data analysis in Python.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">statsmodels</remote-id>
+    <remote-id type="github">statsmodels</remote-id>
+    <remote-id type="sourceforge">statsmodels</remote-id>
+  </upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
diff --git a/dev-python/statsmodels/statsmodels-0.10.2.ebuild b/dev-python/statsmodels/statsmodels-0.10.2.ebuild
new file mode 100644
index 000000000000..dcb371cf4e57
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.10.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.23.0[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "/sphinx.ext.intersphinx/d" -i docs/source/conf.py || die
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx -b html --build-dir=docs/build
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	${EPYTHON} -c 'import statsmodels; statsmodels.test()' || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}
diff --git a/dev-python/statsmodels/statsmodels-0.11.1.ebuild b/dev-python/statsmodels/statsmodels-0.11.1.ebuild
new file mode 100644
index 000000000000..1e97a2638b10
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.11.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.23.0[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/statsmodels-0.11.1-tests.patch"
+)
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter_client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	# these tests require internet
+	sed -i -e 's:test_results_on_the:_&:' \
+		statsmodels/stats/tests/test_dist_dependant_measures.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pushd "${BUILD_DIR}" >/dev/null || die
+	"${EPYTHON}" -c '
+import statsmodels
+statsmodels.test(extra_args=["-vv"], exit=True)' \
+		|| die "tests fail with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}
diff --git a/dev-python/statsmodels/statsmodels-9999.ebuild b/dev-python/statsmodels/statsmodels-9999.ebuild
new file mode 100644
index 000000000000..a5784025a635
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-9999.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 eutils git-r3 virtualx
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/statsmodels/statsmodels.git"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+RDEPEND="${CDEPEND}
+	examples? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+DEPEND="${CDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "/sphinx.ext.intersphinx/d" -i docs/source/conf.py || die
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	export HOME="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx -b html --build-dir=docs/build
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	${EPYTHON} -c 'import statsmodels; statsmodels.test(exit=True)' || die
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}