Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/sqlmodel/sqlmodel-0.0.37.ebuild b/dev-python/sqlmodel/sqlmodel-0.0.37.ebuild
new file mode 100644
index 000000000000..0fb56f94795a
--- /dev/null
+++ b/dev-python/sqlmodel/sqlmodel-0.0.37.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="SQL databases in Python, designed for simplicity, compatibility, and robustness."
+HOMEPAGE="
+	https://sqlmodel.tiangolo.com/
+	https://github.com/fastapi/sqlmodel/
+	https://pypi.org/project/sqlmodel/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/sqlalchemy-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-2.0.14[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2.11.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/fastapi[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/dirty-equals[${PYTHON_USEDEP}]
+		dev-python/jinja2[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Uses coverage
+	# TIP: Search for subprocess.run([coverage])
+	"tests/test_tutorial/test_fastapi/test_app_testing/test_tutorial001_py310_tests_main.py::test_run_tests"
+	"tests/test_tutorial/test_fastapi/test_app_testing/test_tutorial001_py39_tests_main.py::test_run_tests"
+	"tests/test_tutorial/test_fastapi/test_app_testing/test_tutorial001_tests_main.py::test_run_tests"
+	# Updates files
+	"tests/test_select_gen.py::test_select_gen"
+)
+
+EPYTEST_IGNORE=(
+	# Uses coverage
+	# TIP: Search for imports of coverage_run
+	"tests/test_tutorial/test_create_db_and_table/test_tutorial001.py"
+	"tests/test_tutorial/test_create_db_and_table/test_tutorial001_py310.py"
+)
+
+python_test() {
+	epytest tests
+}