Adding metadata

3 files changed, 177 insertions, 6 deletions

diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 0d6a3e2534a0..da5102c54d0b 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -1,4 +1,5 @@
 DIST sqlglot-26.33.0-crates.tar.xz 8859792 BLAKE2B abb2051b392c53dc3caa705ddd8df7076819a26dcdaa89fa3760559a79578db01e86943c2d0ffb8006263c2dca3aa50d20023eae9d772f8ebd12a8a2d3266cdd SHA512 7cca439a06433a62bcd4a2af33d240f46e9b5240cc158edbc654efb37a464aa0f1ebbe9749b2fc6352127b4809b63af2341fac6240050c414e578ae99444ba5d
 DIST sqlglot-26.33.0.tar.gz 5353340 BLAKE2B 18ace866ec89ced24911803497e8cb5c55fc6c157bf62b893e90df914b8be3360403ffff67f196080cdef9b9b9078b86d471494ae9768e7947a8b4d5d39e49af SHA512 df38e899d59bdd07aca0e5370833133308f9c5be4d0c990bf8112a48776fae034b622938aba968769aa5dc5e2957d56da48c89045b91b2d33783e6e25acc4a7b
 DIST sqlglot-27.10.0.tar.gz 5437988 BLAKE2B 600a9bbb94f7fae9bdb0cd8e2e01ffa8d4dd0a113ccd1123bc92b65094d41bf98cb405647fe28ecff63a72401ae10d1a12ef489f063efa7c0aa22f68d754656f SHA512 b6e4eb2c28549c417e8311298d862887205dbcb0e2ff58621988ec904a5e02b6420c69bd5ac8399576207ad799764a2880d09910e42102fef7c21f19a0d8bd89
-DIST sqlglot-27.9.0.tar.gz 5430361 BLAKE2B a64bcdf6c71389694010f6b380418a313f238043e157589cd9479626f8a920bd0d0ff5f8b998353d55ad0ae563d1df37d7b639e094e70abf3640d3401fb4e211 SHA512 c510ffea3f18b1776ddf606a84799cbc63fdb77ee267c9cfd481cf0ad0f971916cadabce5f9cd356c7dc99bbaf8f3468bf903b3ca058e9a18e6e012904d97427
+DIST sqlglot-27.11.0.tar.gz 5443357 BLAKE2B 6af93c7efd402e1ed94fc52d74503945b99e832196d2edd3eb5ee315a7c8ec31d4c3380d5270b78ac8ea54959f4b6dabbad2794d05e78d90588d99195190cc17 SHA512 58ca620725c253f1f917ff468f797d9afb68186b987dc3770c1a78d8a4d59f3d0453a26239e4f0080214316fd1abbb21653c3795a7099f515dae366ab5c4e951
+DIST sqlglot-27.12.0.tar.gz 5450508 BLAKE2B f7eb5b9aebed247f9896cf7e2afe0aa217a2db9c0f25c0527a31769e8921446e6ced1fd7a233fb95db162ade7fb2840404bb31e3197cff62a1b0b6e45c047bcb SHA512 95e6e161b0b586d28ce4ee3470f09b06fef996600b9d6f200fdc5d5a0e844b30166be0efd28fc9cc2f447547d3b53ecbb618e9bd3fe7420f2ba06354135b6c20
diff --git a/dev-python/sqlglot/sqlglot-27.9.0.ebuild b/dev-python/sqlglot/sqlglot-27.11.0.ebuild
index dd19ceb9d941..9a517e6a4e70 100644
--- a/dev-python/sqlglot/sqlglot-27.9.0.ebuild
+++ b/dev-python/sqlglot/sqlglot-27.11.0.ebuild
@@ -154,11 +154,6 @@ python_compile() {
 }
 
 python_test() {
-	local EPYTEST_DESELECT=(
-		# timing, sigh
-		# https://github.com/tobymao/sqlglot/issues/3961
-		tests/test_generator.py::TestGenerator::test_generate_nested_binary
-	)
 	local EPYTEST_IGNORE=(
 		# Tests require pyspark or duckdb which aren't in the tree.
 		# Pandas would be a requirement normally, but it gets ignored by proxy.
diff --git a/dev-python/sqlglot/sqlglot-27.12.0.ebuild b/dev-python/sqlglot/sqlglot-27.12.0.ebuild
new file mode 100644
index 000000000000..9a517e6a4e70
--- /dev/null
+++ b/dev-python/sqlglot/sqlglot-27.12.0.ebuild
@@ -0,0 +1,175 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+	aho-corasick@1.1.3
+	anes@0.1.6
+	anstyle@1.0.10
+	autocfg@1.1.0
+	bumpalo@3.16.0
+	cast@0.3.0
+	cfg-if@1.0.0
+	ciborium-io@0.2.2
+	ciborium-ll@0.2.2
+	ciborium@0.2.2
+	clap@4.5.23
+	clap_builder@4.5.23
+	clap_lex@0.7.4
+	criterion-plot@0.5.0
+	criterion@0.5.1
+	crossbeam-deque@0.8.6
+	crossbeam-epoch@0.9.18
+	crossbeam-utils@0.8.21
+	crunchy@0.2.2
+	either@1.13.0
+	half@2.4.1
+	heck@0.5.0
+	hermit-abi@0.4.0
+	indoc@2.0.4
+	is-terminal@0.4.13
+	itertools@0.10.5
+	itoa@1.0.14
+	js-sys@0.3.76
+	libc@0.2.169
+	log@0.4.22
+	memchr@2.7.4
+	memoffset@0.9.0
+	num-traits@0.2.19
+	once_cell@1.19.0
+	oorandom@11.1.4
+	plotters-backend@0.3.7
+	plotters-svg@0.3.7
+	plotters@0.3.7
+	portable-atomic@1.9.0
+	proc-macro2@1.0.89
+	pyo3-build-config@0.25.0
+	pyo3-ffi@0.25.0
+	pyo3-macros-backend@0.25.0
+	pyo3-macros@0.25.0
+	pyo3@0.25.0
+	quote@1.0.37
+	rayon-core@1.12.1
+	rayon@1.10.0
+	regex-automata@0.4.9
+	regex-syntax@0.8.5
+	regex@1.11.1
+	rustc-hash@2.1.0
+	ryu@1.0.18
+	same-file@1.0.6
+	serde@1.0.216
+	serde_derive@1.0.216
+	serde_json@1.0.133
+	syn@2.0.87
+	target-lexicon@0.13.2
+	tinytemplate@1.2.1
+	unicode-ident@1.0.12
+	unindent@0.2.3
+	walkdir@2.5.0
+	wasm-bindgen-backend@0.2.99
+	wasm-bindgen-macro-support@0.2.99
+	wasm-bindgen-macro@0.2.99
+	wasm-bindgen-shared@0.2.99
+	wasm-bindgen@0.2.99
+	web-sys@0.3.76
+	winapi-util@0.1.9
+	windows-sys@0.52.0
+	windows-sys@0.59.0
+	windows-targets@0.52.6
+	windows_aarch64_gnullvm@0.52.6
+	windows_aarch64_msvc@0.52.6
+	windows_i686_gnu@0.52.6
+	windows_i686_gnullvm@0.52.6
+	windows_i686_msvc@0.52.6
+	windows_x86_64_gnu@0.52.6
+	windows_x86_64_gnullvm@0.52.6
+	windows_x86_64_msvc@0.52.6
+"
+
+CARGO_OPTIONAL=1
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+CRATE_PV=26.33.0
+
+inherit cargo distutils-r1 pypi optfeature
+
+DESCRIPTION="An easily customizable SQL parser and transpiler"
+HOMEPAGE="
+	https://sqlglot.com/
+	https://github.com/tobymao/sqlglot/
+	https://pypi.org/project/sqlglot/
+"
+SRC_URI+="
+	native-extensions? (
+		https://github.com/gentoo-crate-dist/sqlglot/releases/download/v${CRATE_PV}/sqlglot-${CRATE_PV}-crates.tar.xz
+	)
+"
+
+LICENSE="MIT"
+LICENSE+=" native-extensions? ("
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions MIT Unicode-DFS-2016
+"
+LICENSE+=" )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		${RUST_DEPEND}
+		dev-util/maturin[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/sqlglotrs/sqlglotrs.*.so"
+
+pkg_setup() {
+	use native-extensions && rust_pkg_setup
+}
+
+src_unpack() {
+	cargo_src_unpack
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use native-extensions; then
+		local DISTUTILS_USE_PEP517=maturin
+		local DISTUTILS_UPSTREAM_PEP517=maturin
+		cd sqlglotrs || die
+		distutils-r1_python_compile
+		cd - >/dev/null || die
+	fi
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Tests require pyspark or duckdb which aren't in the tree.
+		# Pandas would be a requirement normally, but it gets ignored by proxy.
+		"tests/dataframe/integration/test_dataframe.py"
+		"tests/dataframe/integration/test_grouped_data.py"
+		"tests/dataframe/integration/test_session.py"
+		"tests/test_executor.py"
+		"tests/test_optimizer.py"
+	)
+
+	# make sure not to use an earlier installed version
+	local -x SQLGLOTRS_TOKENIZER=$(usex native-extensions 1 0)
+	rm -rf sqlglotrs || die
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "simplifying timedelta expressions" dev-python/python-dateutil
+}