Updating liguros repo

5 files changed, 147 insertions, 0 deletions

diff --git a/dev-python/secretstorage/Manifest b/dev-python/secretstorage/Manifest
new file mode 100644
index 000000000000..b97541e4e074
--- /dev/null
+++ b/dev-python/secretstorage/Manifest
@@ -0,0 +1,2 @@
+DIST SecretStorage-3.1.1.tar.gz 17036 BLAKE2B 1dda10a5f74727ec29392ff2a3ec65b841aff86db21223ebdbf291afcc9ac7ee68de8c62e5929aa45aafabc791ac02ed80b6785e69f2d4b51d827fce8bbb3443 SHA512 295e0f75c772edf153480730dc20051f06e60e040a18f169620cb4aaa37b8c1a254a496464d3794a38cf49fa884a7b561fe364816f0d12a5b2622c77259f03cf
+DIST SecretStorage-3.1.2.tar.gz 17848 BLAKE2B 3d108f98fd0c26958860aa65554a21924822a5d51a90ae20c5496792f4571babbdfd2aec5b70d1bdd908498ad1b61606130d5db2900406ae85f8e3367ad3013f SHA512 c132b21556c55b5912354fd27b6062d32c0f510234f7fe57f6e8e0acb08393ad95e0896967b577de97821387cd714e62b657359230296449e4e0a7ae5a797803
diff --git a/dev-python/secretstorage/metadata.xml b/dev-python/secretstorage/metadata.xml
new file mode 100644
index 000000000000..c25b03991500
--- /dev/null
+++ b/dev-python/secretstorage/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">SecretStorage</remote-id>
+		<remote-id type="github">mitya57/secretstorage</remote-id>
+	</upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
diff --git a/dev-python/secretstorage/secretstorage-3.1.1-r1.ebuild b/dev-python/secretstorage/secretstorage-3.1.1-r1.ebuild
new file mode 100644
index 000000000000..c2c16164332f
--- /dev/null
+++ b/dev-python/secretstorage/secretstorage-3.1.1-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="SecretStorage"
+
+DESCRIPTION="Python bindings to FreeDesktop.org Secret Service API."
+HOMEPAGE="https://github.com/mitya57/secretstorage https://pypi.org/project/SecretStorage/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/jeepney[${PYTHON_USEDEP}]
+"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+python_test() {
+	dbus-run-session "${EPYTHON}" -m unittest discover -v -s tests \
+		|| die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/secretstorage/secretstorage-3.1.1.ebuild b/dev-python/secretstorage/secretstorage-3.1.1.ebuild
new file mode 100644
index 000000000000..a70df4c44296
--- /dev/null
+++ b/dev-python/secretstorage/secretstorage-3.1.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7} )
+
+inherit distutils-r1
+
+MY_PN="SecretStorage"
+
+DESCRIPTION="Python bindings to FreeDesktop.org Secret Service API."
+HOMEPAGE="https://github.com/mitya57/secretstorage https://pypi.org/project/SecretStorage/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/jeepney[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/alabaster[${PYTHON_USEDEP}]
+	)
+	test? ( ${RDEPEND} )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	dbus-run-session "${EPYTHON}" -m unittest discover -v -s tests \
+		|| die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/secretstorage/secretstorage-3.1.2.ebuild b/dev-python/secretstorage/secretstorage-3.1.2.ebuild
new file mode 100644
index 000000000000..571eb1a98f0c
--- /dev/null
+++ b/dev-python/secretstorage/secretstorage-3.1.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8,9} )
+
+inherit distutils-r1
+
+MY_PN="SecretStorage"
+
+DESCRIPTION="Python bindings to FreeDesktop.org Secret Service API."
+HOMEPAGE="https://github.com/mitya57/secretstorage https://pypi.org/project/SecretStorage/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/jeepney-0.4.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( !hppa? ( !sparc? (
+		gnome-base/gnome-keyring
+		sys-apps/dbus
+	) ) )
+"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+src_test() {
+	case ${ARCH} in
+		hppa|sparc)
+			einfo "gnome-keyring is not supported on ${ARCH}, skipping tests"
+			return
+			;;
+	esac
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	dbus-run-session "${EPYTHON}" -m unittest discover -v -s tests \
+		|| die "tests failed with ${EPYTHON}"
+}