Adding metadata

4 files changed, 88 insertions, 2 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index 8e17cdc23e58..01b88fbb82f6 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.8.0.gh.tar.gz 7321445 BLAKE2B 3010843f019f97a845eb4184dbb0225bc6ef36e5af374811ea08492a78a85ece7ac5cf543c6bd33bad8faf6adbb2ea2412b3ea04e3a30cb7ea6b3d63da1a95a2 SHA512 801985d472894f896e9f277bbdef76388d9a53d821eaede95c43850d8e812d0a5cbaf16c15f2e495ec569a070f727b12729e346775e278afa11c30c713effb62
+DIST scikit-learn-1.9.0rc1.gh.tar.gz 7733487 BLAKE2B 17c7241207ed29c4a9554a45ba720cf948df88ebfce0c38168073bde32e9cac0113401b6b315756a0104216d09e9918d3d45ac89fc87379100ccf62d8852eaad SHA512 e0a230be466333d27c4a75a56b64ba818a065818f7a4997278ab86c2e40f9734656898d9fe96c4e7b3bef1cd3eb9b83995c52b9051fed93b1df7e0ce7ce46c32
diff --git a/dev-python/scikit-learn/metadata.xml b/dev-python/scikit-learn/metadata.xml
index eb2fd0813fed..21b19a515c2b 100644
--- a/dev-python/scikit-learn/metadata.xml
+++ b/dev-python/scikit-learn/metadata.xml
@@ -15,5 +15,5 @@
 		and efficient.
 	</longdescription>
  
- <origin>gentoo-staging</origin>
+ <origin>liguros-repo</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
index 82eb7c34ee9e..0f3d75279cf6 100644
--- a/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
+++ b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=meson-python
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{12..14} )
 
 inherit distutils-r1
 
diff --git a/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild b/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild
new file mode 100644
index 000000000000..d7edd6753fc8
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2020-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV/_}.tar.gz
+		-> ${P/_}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_}
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.24.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/narwhals-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	case ${ARCH} in
+		ppc64)
+			EPYTEST_DESELECT+=(
+				# TODO
+				ensemble/_weight_boosting.py::sklearn.ensemble._weight_boosting.AdaBoostRegressor
+			)
+	esac
+
+	rm -rf sklearn || die
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}