Adding metadata

2 files changed, 77 insertions, 0 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index 722d4adfb74f..5a7b56d1d2db 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.6.0.gh.tar.gz 7058791 BLAKE2B 57a81223d4cd2ac60cf00829f0e9b3fc404341428ec5ebbdf187f6c69213d90bf541ee6bf69a7dbe6e68225d34cf393302b098cc62e44068515b22d9e6462549 SHA512 7301503d581f908d7d70c708c44d5ec39567628c9f05a4135d69864a6bff6252fe1af6aac9c87c4c829c7e98008bab6fe964bcab6a3bb617996dc8368bb4fa60
+DIST scikit-learn-1.6.1.gh.tar.gz 7046495 BLAKE2B 83292549cc12e44033451345fe6deac17fa4f3d013f9755839d4d7f1c7de9690c089a754493d0d3879ef44ed8523400d617fa4d135ce8500dab608552777cdf6 SHA512 ad91d7bd67884851334fed9b0f3b6f3bfacb6b1521b89acbe22e9428a88009579373118bbd3a55358ea60c997e98609062fc4eac8b1def1d0ad18026c0491074
diff --git a/dev-python/scikit-learn/scikit-learn-1.6.1.ebuild b/dev-python/scikit-learn/scikit-learn-1.6.1.ebuild
new file mode 100644
index 000000000000..6e134401fa29
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.6.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.19.5:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+		# doctest failing on extra shape= in repr, probably numpy version
+		cluster/_hdbscan/hdbscan.py::sklearn.cluster._hdbscan.hdbscan.HDBSCAN
+	)
+
+	rm -rf sklearn || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}