Adding metadata

4 files changed, 88 insertions, 2 deletions

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index 01b88fbb82f6..2e8e39cfd5e6 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1,2 +1,3 @@
 DIST scikit-learn-1.8.0.gh.tar.gz 7321445 BLAKE2B 3010843f019f97a845eb4184dbb0225bc6ef36e5af374811ea08492a78a85ece7ac5cf543c6bd33bad8faf6adbb2ea2412b3ea04e3a30cb7ea6b3d63da1a95a2 SHA512 801985d472894f896e9f277bbdef76388d9a53d821eaede95c43850d8e812d0a5cbaf16c15f2e495ec569a070f727b12729e346775e278afa11c30c713effb62
+DIST scikit-learn-1.9.0.gh.tar.gz 7731588 BLAKE2B 1d0861355b9a41f15b75d0cdcb2dc29e68e8d74943c2512dffca9a7f226e4306ab72c469a186e8262f97af249f3c260d7ec0d54e566e5ff1dfe7d5a41dc8e3d7 SHA512 27976d83841d3ea939c9193445d7d81a13de54d466851c94325c576e27de0959a3440347d8c342fec5c7f94476acb68b1056e4e0cca894e23a2ac783014b783f
 DIST scikit-learn-1.9.0rc1.gh.tar.gz 7733487 BLAKE2B 17c7241207ed29c4a9554a45ba720cf948df88ebfce0c38168073bde32e9cac0113401b6b315756a0104216d09e9918d3d45ac89fc87379100ccf62d8852eaad SHA512 e0a230be466333d27c4a75a56b64ba818a065818f7a4997278ab86c2e40f9734656898d9fe96c4e7b3bef1cd3eb9b83995c52b9051fed93b1df7e0ce7ce46c32
diff --git a/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
index 0f3d75279cf6..ca548613e272 100644
--- a/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
+++ b/dev-python/scikit-learn/scikit-learn-1.8.0.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=meson-python
-PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_COMPAT=( python3_{13..14} )
 
 inherit distutils-r1
 
diff --git a/dev-python/scikit-learn/scikit-learn-1.9.0.ebuild b/dev-python/scikit-learn/scikit-learn-1.9.0.ebuild
new file mode 100644
index 000000000000..f3d779913db2
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.9.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2020-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV/_}.tar.gz
+		-> ${P/_}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_}
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.24.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/narwhals-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	case ${ARCH} in
+		ppc64)
+			EPYTEST_DESELECT+=(
+				# TODO
+				ensemble/_weight_boosting.py::sklearn.ensemble._weight_boosting.AdaBoostRegressor
+			)
+	esac
+
+	rm -rf sklearn || die
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}
diff --git a/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild b/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild
index d7edd6753fc8..f3d779913db2 100644
--- a/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild
+++ b/dev-python/scikit-learn/scikit-learn-1.9.0_rc1.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=meson-python
-PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_COMPAT=( python3_{13..14} )
 
 inherit distutils-r1