Adding metadata

3 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/scikit-build/Manifest b/dev-python/scikit-build/Manifest
new file mode 100644
index 000000000000..38ef329380fc
--- /dev/null
+++ b/dev-python/scikit-build/Manifest
@@ -0,0 +1,2 @@
+DIST scikit_build-0.19.0.tar.gz 274552 BLAKE2B 961436b23d39ea5c6b7f8258da3a10b03e265155ef4e312a69dc7a423dc8cb2ce837f547dbaeaf8902e36ab04736f71ef4e092fb8b6bdca2c601f9728aa777e1 SHA512 3201789ae996603ded40fc997d3df712b440e7242d8ed04f027aa05ac66788c19725a7736e4296429095464024f1b06e6258fc5c7b31879496264bf56e2df51b
+DIST scikit_build-0.19.0.tar.gz.provenance 9674 BLAKE2B 328eac64356a2e06650c15e3314985401a7d24fcd502f9bd6855c70664d0b3096ffd2e5be25aec14cfc18558f647b1940491dd3626363d3d347d20c347fee7eb SHA512 748553c323cb4d44128497c4c460072e63c86082e7e33d2655ad9348aa0fc4d7a34aba1ef243279f0ff68900cd5133ca8441e75b12351e9a4d27279bcc79aeda
diff --git a/dev-python/scikit-build/metadata.xml b/dev-python/scikit-build/metadata.xml
new file mode 100644
index 000000000000..d50157552fb4
--- /dev/null
+++ b/dev-python/scikit-build/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/scikit-build/scikit-build-0.19.0.ebuild b/dev-python/scikit-build/scikit-build-0.19.0.ebuild
new file mode 100644
index 000000000000..d503d53cb15d
--- /dev/null
+++ b/dev-python/scikit-build/scikit-build-0.19.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/scikit-build/scikit-build
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build/
+	https://pypi.org/project/scikit-build/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-42.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.7[${PYTHON_USEDEP}]
+		>=dev-python/cython-0.25.1[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme \
+	dev-python/sphinx-issues
+# note: tests are unstable with xdist
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	# not packaged
+	sed -i -e '/cmakedomain/d' docs/conf.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+
+	local EPYTEST_DESELECT=(
+		# Internet (via new setuptools?)
+		tests/test_hello_cpp.py::test_hello_develop
+	)
+
+	# create a separate test tree since skbuild tests install random stuff
+	cp -r "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test${EPREFIX}/usr/bin:${PATH}
+
+	epytest -m "not isolated and not nosetuptoolsscm" \
+		-o tmp_path_retention_count=1
+}