Adding metadata

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/s3transfer/s3transfer-0.19.2-r1.ebuild b/dev-python/s3transfer/s3transfer-0.19.2-r1.ebuild
new file mode 100644
index 000000000000..7917529222f3
--- /dev/null
+++ b/dev-python/s3transfer/s3transfer-0.19.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="An Amazon S3 Transfer Manager"
+HOMEPAGE="
+	https://github.com/boto/s3transfer/
+	https://pypi.org/project/s3transfer/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/botocore-2[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.37.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/awscrt[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+}
+
+python_test() {
+	epytest tests/{unit,functional}
+}