Adding metadata

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index 20a55546419d..de6436de4326 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-2.7.0.tar.gz 679396 BLAKE2B b304624e88e6c2f636dc2bb69da845ffa12b40e27ac1a6198e56217233b61b3fee64c9c59e48388710408b43d6de6187881f8b6ed83ed04b783d848bd8fff234 SHA512 323a7b9f9d8ee2a74434d647db131c20d975f93215993c0410574f075fc5f6f340ebb4480c8acf8102944c13c0e699309baaf1a2b9a9f6a71367e0c772896ecb
+DIST rq-2.8.0.tar.gz 743395 BLAKE2B bbc71e84b3bc5e52b7db2330ba9fa8313a429eeda93f2b884dfc9303e27738eb60aee2ad4d647bd5aedb771edee578bca2810f9a97d9cf5f8aa056342ef5d78f SHA512 e48a349be9d6f7151c32d183ffe0bc883fa395b988b7c607ffedcdaad19b5da1af78d0cd14d1de9029f1dd82a6a26419cfe2a668ab491e73b948f8568e1e3245
diff --git a/dev-python/rq/rq-2.8.0.ebuild b/dev-python/rq/rq-2.8.0.ebuild
new file mode 100644
index 000000000000..03d1ff885aeb
--- /dev/null
+++ b/dev-python/rq/rq-2.8.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	dev-python/croniter[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires <sentry-sdk-2
+	tests/test_sentry.py::TestSentry::test_failure_capture
+	# hang
+	tests/test_commands.py::TestCommands::test_shutdown_command
+	tests/test_worker_pool.py::TestWorkerPool::test_check_workers
+	tests/test_worker_pool.py::TestWorkerPool::test_reap_workers
+	tests/test_dependencies.py::TestDependencies
+	# already present in older versions
+	tests/test_spawn_worker.py::TestWorker::test_work_and_quit
+)
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip pin
+	sed -i -e '/dependencies/s:,!=[0-9.]*::' pyproject.toml || die
+}
+
+src_test() {
+	local -x TZ=UTC
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}