Adding metadata

4 files changed, 145 insertions, 4 deletions

diff --git a/dev-python/qtconsole/Manifest b/dev-python/qtconsole/Manifest
index d669fa3d1c4c..c15dc441bb26 100644
--- a/dev-python/qtconsole/Manifest
+++ b/dev-python/qtconsole/Manifest
@@ -1 +1,2 @@
 DIST qtconsole-5.4.3.tar.gz 437303 BLAKE2B ead6676dabf342a74c30ecba1f280e697c7e58fb970813a572bcacf4adbc71e525df4323b50c30100433373e89eeea464dc382844066416e121a0f1c140487db SHA512 9c2061441775daa3045c1788ed57048de9197938a927647197d29a0b7cada836d5fe4e3329b5126c984064070a275cccbe0341622c3b8591f63842a619b859e8
+DIST qtconsole-5.4.4.tar.gz 437213 BLAKE2B 2def481c7ceb29c8ce92dfb96055310a8ee3a664a77c76da0eac672c6fd036326402a47cdaab25d504a855172067ae73e7f94b874545951674395d82f18374b5 SHA512 95d00a7896579eeba75896dd96efe9f07a54a687eca4ec2c4d9c7cf05029570788cd23267682ee4bce9943cf4d6cb36d7bd1d77be66f6bfd0f37e7d15e0d8f0f
diff --git a/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild b/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild
new file mode 100644
index 000000000000..b689386653df
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-5.4.3-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/qtconsole/
+	https://pypi.org/project/qtconsole/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.1[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-4.1.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2_p1[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.0.1[${PYTHON_USEDEP},gui,printsupport,svg]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/QtPy[${PYTHON_USEDEP},svg,testlib]
+	)
+"
+
+PDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO; expects exact HTML, so perhaps fragile
+		qtconsole/tests/test_jupyter_widget.py::TestJupyterWidget::test_other_output
+	)
+	local -x QT_API
+	for QT_API in pyqt5 pyqt6 pyside2 pyside6; do
+		if has_version "dev-python/QtPy[${QT_API}]"; then
+			local -x PYTEST_QT_API=${QT_API}
+			einfo "Testing with ${QT_API}"
+			nonfatal epytest ||
+				die "Tests failed with ${EPYTHON} / ${QT_API}"
+		fi
+	done
+}
diff --git a/dev-python/qtconsole/qtconsole-5.4.3.ebuild b/dev-python/qtconsole/qtconsole-5.4.3.ebuild
index 57c2984e60c1..136235d4ae5c 100644
--- a/dev-python/qtconsole/qtconsole-5.4.3.ebuild
+++ b/dev-python/qtconsole/qtconsole-5.4.3.ebuild
@@ -31,10 +31,9 @@ RDEPEND="
 	>=dev-python/traitlets-5.2.2_p1[${PYTHON_USEDEP}]
 	>=dev-python/QtPy-2.0.1[${PYTHON_USEDEP},gui,printsupport,svg]
 "
-# The test suite tests both against pyqt5 *and* pyside2
 BDEPEND="
 	test? (
-		dev-python/QtPy[pyqt5,pyside2,${PYTHON_USEDEP},svg,testlib]
+		dev-python/QtPy[${PYTHON_USEDEP},svg,testlib]
 	)
 "
 # required by the tests that are removed:
@@ -51,9 +50,16 @@ distutils_enable_tests pytest
 python_test() {
 	# TODO: these tests require virtx; however, running under virtx
 	# causes pytest to segv on exit (even though tests pass)
-	EPYTEST_IGNORE=(
+	local EPYTEST_IGNORE=(
 		qtconsole/tests/test_00_console_widget.py
 		qtconsole/tests/test_jupyter_widget.py
 	)
-	epytest
+	local -x QT_API
+	for QT_API in pyqt5 pyqt6 pyside2 pyside6; do
+		if has_version "dev-python/QtPy[${QT_API}]"; then
+			local -x PYTEST_QT_API=${QT_API}
+			einfo "Testing with ${QT_API}"
+			epytest
+		fi
+	done
 }
diff --git a/dev-python/qtconsole/qtconsole-5.4.4.ebuild b/dev-python/qtconsole/qtconsole-5.4.4.ebuild
new file mode 100644
index 000000000000..0649d24cec41
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-5.4.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/qtconsole/
+	https://pypi.org/project/qtconsole/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.1[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-4.1.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2_p1[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.4.0[${PYTHON_USEDEP},gui,printsupport,svg]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/QtPy[${PYTHON_USEDEP},svg,testlib]
+	)
+"
+
+PDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO; expects exact HTML, so perhaps fragile
+		qtconsole/tests/test_jupyter_widget.py::TestJupyterWidget::test_other_output
+	)
+	local -x QT_API
+	for QT_API in pyqt5 pyqt6 pyside2 pyside6; do
+		if has_version "dev-python/QtPy[${QT_API}]"; then
+			local -x PYTEST_QT_API=${QT_API}
+			einfo "Testing with ${QT_API}"
+			nonfatal epytest ||
+				die "Tests failed with ${EPYTHON} / ${QT_API}"
+		fi
+	done
+}