Updating liguros repo

3 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/qdarkstyle/Manifest b/dev-python/qdarkstyle/Manifest
new file mode 100644
index 000000000000..ed582f0bbc8c
--- /dev/null
+++ b/dev-python/qdarkstyle/Manifest
@@ -0,0 +1 @@
+DIST qdarkstyle-2.8.1.tar.gz 7883937 BLAKE2B fd5a35467c6c47e9eb135d4a119b3f382bfe20b9b0ac2d407fef7113e5ce4d914f3d8e462d26a71b8f1494f42b71a4f8819b0eb2c6579d87ca9dd497d09d39d7 SHA512 10c3f834b1ea50f665c2ce3fde16533c7dfc62c2d055afcc7d2434c09d14fb9a6181b73ce12d3af72897b9d26b41db81cc76e7c7cb6112eef097cd86630b6532
diff --git a/dev-python/qdarkstyle/metadata.xml b/dev-python/qdarkstyle/metadata.xml
new file mode 100644
index 000000000000..70b87a6748a5
--- /dev/null
+++ b/dev-python/qdarkstyle/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+	<maintainer type="person">
+		<email>andrewammerlaan@riseup.net</email>
+		<name>Andrew Ammerlaan</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
diff --git a/dev-python/qdarkstyle/qdarkstyle-2.8.1.ebuild b/dev-python/qdarkstyle/qdarkstyle-2.8.1.ebuild
new file mode 100644
index 000000000000..9e29ded805c9
--- /dev/null
+++ b/dev-python/qdarkstyle/qdarkstyle-2.8.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit eutils distutils-r1
+
+MY_PN="QDarkStyleSheet"
+
+DESCRIPTION="A dark style sheet for QtWidgets application"
+HOMEPAGE="https://github.com/ColinDuquesnoy/QDarkStyleSheet"
+SRC_URI="https://github.com/ColinDuquesnoy/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="examples"
+
+RDEPEND=">=dev-python/helpdev-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-1.7[${PYTHON_USEDEP}]"
+
+DEPEND="test? ( dev-python/qtsass[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx_rtd_theme dev-python/m2r
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	#/var/tmp/portage/dev-python/qdarkstyle-2.8/temp/environment: line 2949:    66 Aborted  (core dumped) pytest -vv
+	sed -i -e 's:test_create_custom_qss:_&:' \
+		test/test_sass_compiler.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# tests look for a file in source dir that is not installed
+	PYTHONPATH="${S}"
+	cd "${S}" || die
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && dodoc -r example
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "qdarkstyle.utils" dev-python/qtsass
+}