Adding metadata

3 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/pyzmq/Manifest b/dev-python/pyzmq/Manifest
index 223775ad687b..761935c79bdd 100644
--- a/dev-python/pyzmq/Manifest
+++ b/dev-python/pyzmq/Manifest
@@ -1 +1,2 @@
 DIST pyzmq-22.1.0.gh.tar.gz 401919 BLAKE2B ec43c62e68633a7e0ac06e7a717b6409e444dbd1347154c2a29a2dfb00916829656308122fa2cf0fc1e3013c82ba6bcc5e11b86582f95d46f43e9e81f6d8ff74 SHA512 aa135279927bff07339b99b4ebbc7d47effbfba7df99d3576088fe0e7d4a3ad44174a928e8b94afdeaf531c6a30cbb7bb88bce7fe19e7e5420b079ffb8e8690e
+DIST pyzmq-23.0.0.gh.tar.gz 399818 BLAKE2B ebd99acb5270f4ba2f851f3df9a7cb81f986730eba81d54c2c4bc55f24f98ebafdd7a24fcdce1dc5727a1e2e1ce57a9b52160800c6eb29c08bb9ee94450c5a83 SHA512 aaee7af933467daf56db660b84cf79972042aee6b2c9640c00e09e0d7c78cafe61346df567beb8eebadb4408c1887eb355beee04c4a6b1efa0d8dde8a4c82283
diff --git a/dev-python/pyzmq/metadata.xml b/dev-python/pyzmq/metadata.xml
index ad80622e5b0d..3e05ff1fff7f 100644
--- a/dev-python/pyzmq/metadata.xml
+++ b/dev-python/pyzmq/metadata.xml
@@ -5,6 +5,10 @@
   <email>python@gentoo.org</email>
   <name>Python</name>
  </maintainer>
+ <maintainer type="person">
+  <email>andrewammerlaan@gentoo.org</email>
+  <name>Andrew Ammerlaan</name>
+ </maintainer>
  
  <use>
   <flag name="draft">Enable draft API support</flag>
diff --git a/dev-python/pyzmq/pyzmq-23.0.0.ebuild b/dev-python/pyzmq/pyzmq-23.0.0.ebuild
new file mode 100644
index 000000000000..1aebe04d93cb
--- /dev/null
+++ b/dev-python/pyzmq/pyzmq-23.0.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+# TODO: Find out exactly where this error comes from
+# error: '<' not supported between instances of 'str' and 'int'
+#DISTUTILS_USE_PEP517=setuptools
+PYTHON_REQ_USE="threads(+)"
+
+inherit flag-o-matic distutils-r1 toolchain-funcs
+
+DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="
+	https://zeromq.org/languages/python/
+	https://pypi.org/project/pyzmq/
+	https://github.com/zeromq/pyzmq/"
+SRC_URI="
+	https://github.com/zeromq/pyzmq/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+draft"
+
+DEPEND="
+	>=net-libs/zeromq-4.2.2-r2:=[drafts]
+"
+# it uses cffi backend for pypy, cython backend for cpython
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/py[${PYTHON_USEDEP}]
+		dev-python/cffi:=[${PYTHON_USEDEP}]
+	' pypy3)
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/cython[${PYTHON_USEDEP}]
+	' 'python*')
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=www-servers/tornado-5.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	"dev-python/numpydoc"
+
+python_configure_all() {
+	tc-export CC
+	append-cppflags -DZMQ_BUILD_DRAFT_API=$(usex draft '1' '0')
+}
+
+python_compile() {
+	esetup.py cython --force
+	ZMQ_PREFIX="${EPREFIX}/usr" distutils-r1_python_compile
+}
+
+python_test() {
+	EPYTEST_DESELECT=(
+		# TODO
+		zmq/tests/test_constants.py::TestConstants::test_draft
+		zmq/tests/test_cython.py::test_cython
+
+		# hangs often
+		zmq/tests/test_log.py::TestPubLog::test_blank_root_topic
+	)
+	EPYTEST_IGNORE=(
+		zmq/tests/test_mypy.py
+	)
+
+	cd "${BUILD_DIR}/lib" || die
+	epytest
+}