Adding metadata

3 files changed, 0 insertions, 105 deletions

diff --git a/dev-python/pyzmq/Manifest b/dev-python/pyzmq/Manifest
deleted file mode 100644
index a008e36767e4..000000000000
--- a/dev-python/pyzmq/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST pyzmq-27.1.0.gh.tar.gz 283119 BLAKE2B 0d9115c32f93ca4f204030afbec3ac2e86efaadfe0d6293a0c7af81737558df8cd1b33506294ca3249a111c33333423b344c668ae32acd206cce792b2128e291 SHA512 621f7374861198dfddf1f667e4af24dd874a239a623961c27c148b1e525492d409ba830a3bfe5cf8eed1d61a094b3993daf6911fb11734e398d7594b15c06543
diff --git a/dev-python/pyzmq/metadata.xml b/dev-python/pyzmq/metadata.xml
deleted file mode 100644
index 0e45733b1531..000000000000
--- a/dev-python/pyzmq/metadata.xml
+++ /dev/null
@@ -1,19 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>python@gentoo.org</email>
-		<name>Python</name>
-	</maintainer>
-	<maintainer type="person">
-		<email>nowa@gentoo.org</email>
-		<name>Nowa Ammerlaan</name>
-	</maintainer>
-	<upstream>
-		<remote-id type="pypi">pyzmq</remote-id>
-		<remote-id type="github">zeromq/pyzmq</remote-id>
-	</upstream>
-	<use>
-		<flag name="drafts">Enable draft API support</flag>
-	</use>
-</pkgmetadata>
diff --git a/dev-python/pyzmq/pyzmq-27.1.0.ebuild b/dev-python/pyzmq/pyzmq-27.1.0.ebuild
deleted file mode 100644
index 2dd3cdd0f382..000000000000
--- a/dev-python/pyzmq/pyzmq-27.1.0.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=scikit-build-core
-PYTHON_COMPAT=( python3_{13..14} )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
-HOMEPAGE="
-	https://zeromq.org/languages/python/
-	https://pypi.org/project/pyzmq/
-	https://github.com/zeromq/pyzmq/
-"
-SRC_URI="
-	https://github.com/zeromq/pyzmq/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
-IUSE="drafts"
-
-# There are additional test failures if zeromq has the draft api enabled, but pyzmq has it disabled.
-DEPEND="
-	>=net-libs/zeromq-4.2.2-r2:=[drafts=]
-"
-# It uses cffi backend for pypy, cython backend for cpython
-RDEPEND="
-	${DEPEND}
-"
-BDEPEND="
-	dev-python/packaging[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
-	' 'python*')
-	test? (
-		>=dev-python/tornado-5.0.2[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-{asyncio,rerunfailures} )
-distutils_enable_tests pytest
-# TODO: Package enum_tools
-# distutils_enable_sphinx docs/source \
-# 	dev-python/numpydoc \
-# 	dev-python/sphinx-rtd-theme \
-# 	dev-python/myst-parser
-
-src_configure() {
-	DISTUTILS_ARGS=(
-		-DZMQ_DRAFT_API="$(usex drafts)"
-		-DPYZMQ_NO_BUNDLE=ON
-		# unnecessarily adds /usr/lib* to rpath
-		-DPYZMQ_LIBZMQ_RPATH=OFF
-	)
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# often crashes zmq?
-		tests/test_log.py::TestPubLog
-	)
-	local EPYTEST_IGNORE=(
-		# Avoid dependency on mypy
-		tests/test_mypy.py
-	)
-
-	case ${EPYTHON} in
-		pypy3*)
-			EPYTEST_DESELECT+=(
-				# not implemented in cffi variant?
-				tests/test_draft.py::TestDraftSockets
-			)
-	esac
-
-	rm -rf zmq || die
-	# avoid large to reduce memory consumption
-	epytest tests -m "not large"
-}