Adding metadata

4 files changed, 99 insertions, 0 deletions

diff --git a/dev-python/pyx/Manifest b/dev-python/pyx/Manifest
new file mode 100644
index 000000000000..0af7a58528ac
--- /dev/null
+++ b/dev-python/pyx/Manifest
@@ -0,0 +1 @@
+DIST pyx-0.16.gh.tar.gz 626703 BLAKE2B fa1f1a54e958fa4c1c3efd1df4cf744a1d591ac17671a6da4b2d2f15ae5f2a6cb6260bd1c5f189c60b0683e4f54545f5d3c0ed0c7698f14fa390396c18bf4ebd SHA512 613212a7a7d983432aab574bdccd402132da2b1ae563cb672e2766dbcda3ce91977780ab5e4097de77e6499d36537b54089327e448cf4e7855889087c3b9a9f8
diff --git a/dev-python/pyx/files/pyx-0.14.1-unicode-latex.patch b/dev-python/pyx/files/pyx-0.14.1-unicode-latex.patch
new file mode 100644
index 000000000000..6495eb499b7c
--- /dev/null
+++ b/dev-python/pyx/files/pyx-0.14.1-unicode-latex.patch
@@ -0,0 +1,10 @@
+diff -r -U1 PyX-0.14.1.orig/faq/general_aspects_pyx.rst PyX-0.14.1/faq/general_aspects_pyx.rst
+--- PyX-0.14.1.orig/faq/general_aspects_pyx.rst	2015-11-02 23:19:54.000000000 +0100
++++ PyX-0.14.1/faq/general_aspects_pyx.rst	2018-03-19 16:45:16.432663630 +0100
+@@ -15,4 +15,4 @@
+ Despite the ties between TeX and PyX, their pronunciation is quite different.
+-According to the developers of PyX, it should be pronounced as [pʏks]. Please do
+-not pronounce it as [pʏx] or [pʏç].
++According to the developers of PyX, it should be pronounced as [pyks]. Please do
++not pronounce it as [pyx] or [pyç].
+ 
diff --git a/dev-python/pyx/metadata.xml b/dev-python/pyx/metadata.xml
new file mode 100644
index 000000000000..33aa8545a937
--- /dev/null
+++ b/dev-python/pyx/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>grozin@gentoo.org</email>
+    <name>Andrey Grozin</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription>
+PyX is a Python package for the creation of encapsulated PostScript figures.
+It provides both an abstraction of PostScript and a TeX/LaTeX interface.
+Complex tasks like 2d and 3d plots in publication-ready quality are built out
+of these primitives.
+	</longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pyx/pyx-0.16-r2.ebuild b/dev-python/pyx/pyx-0.16-r2.ebuild
new file mode 100644
index 000000000000..80011b3febe8
--- /dev/null
+++ b/dev-python/pyx/pyx-0.16-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python package for the generation of encapsulated PostScript figures"
+MY_PN="PyX"
+MY_P=${MY_PN}-${PV}
+HOMEPAGE="
+	https://github.com/pyx-project/pyx
+	https://pyx-project.org/
+	https://pypi.org/project/PyX/"
+SRC_URI="https://github.com/pyx-project/${PN}/releases/download/${PV}/${MY_P}.tar.gz -> ${P}.gh.tar.gz"
+
+S="${WORKDIR}"/${MY_P}
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+	virtual/tex-base
+	virtual/latex-base
+	dev-texlive/texlive-basic"
+
+BDEPEND="${RDEPEND}
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[latex,${PYTHON_USEDEP}]
+			dev-python/sphinx-selective-exclude[${PYTHON_USEDEP}]
+		')
+	)"
+
+PATCHES=( "${FILESDIR}"/pyx-0.14.1-unicode-latex.patch )
+
+python_check_deps() {
+	use doc || return 0
+	python_has_version "dev-python/sphinx[latex,${PYTHON_USEDEP}]" \
+		"dev-python/sphinx-selective-exclude[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	sed -i \
+		-e 's/^build_t1code=.*/build_t1code=1/' \
+		-e 's/^build_pykpathsea=.*/build_pykpathsea=1/' \
+		setup.cfg || die "setup.cfg fix failed"
+	distutils-r1_src_prepare
+}
+
+python_compile_all() {
+	if use doc; then
+		local -x VARTEXFONTS="${T}"/fonts
+		PYTHONPATH="${WORKDIR}"/${MY_P}-${EPYTHON/./_}/install/usr/lib/${EPYTHON}/site-packages \
+			emake -C "${S}"/manual latexpdf
+		PYTHONPATH="${WORKDIR}"/${MY_P}-${EPYTHON/./_}/install/usr/lib/${EPYTHON}/site-packages \
+			emake -C "${S}"/faq latexpdf
+	fi
+}
+
+python_install_all() {
+	use doc && dodoc manual/_build/latex/manual.pdf faq/_build/latex/pyxfaq.pdf
+	distutils-r1_python_install_all
+}