Adding metadataHEADdevelop

1 files changed, 97 insertions, 0 deletions

diff --git a/dev-python/python-subunit/python-subunit-1.4.5-r1.ebuild b/dev-python/python-subunit/python-subunit-1.4.5-r1.ebuild
new file mode 100644
index 000000000000..5393f9181560
--- /dev/null
+++ b/dev-python/python-subunit/python-subunit-1.4.5-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 multilib-minimal autotools
+
+MY_P=subunit-${PV}
+DESCRIPTION="A streaming protocol for test results"
+HOMEPAGE="
+	https://launchpad.net/subunit/
+	https://github.com/testing-cabal/subunit/
+	https://pypi.org/project/python-subunit/
+"
+SRC_URI="
+	https://github.com/testing-cabal/subunit/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
+	dev-python/iso8601[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
+	>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
+	>=virtual/pkgconfig-0-r1
+	test? (
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		<dev-python/testtools-2.9[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/subunit-1.4.0-werror.patch"
+	# https://github.com/testing-cabal/subunit/commit/a72e9c343bd369cf840b29e074417fed5d05d59c
+	"${FILESDIR}/subunit-1.4.5-testtools-2.8.patch"
+)
+
+src_prepare() {
+	mv all_tests.py python/ || die
+
+	distutils-r1_src_prepare
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+multilib_src_compile() {
+	default
+	multilib_is_native_abi && distutils-r1_src_compile
+}
+
+python_test() {
+	cd python || die
+	"${EPYTHON}" -m testtools.run -v all_tests.test_suite ||
+		die "Testing failed with ${EPYTHON}"
+}
+
+multilib_src_test() {
+	multilib_is_native_abi && distutils-r1_src_test
+}
+
+multilib_src_install() {
+	local targets=(
+		install-include_subunitHEADERS
+		install-pcdataDATA
+		install-libLTLIBRARIES
+	)
+	emake DESTDIR="${D}" "${targets[@]}"
+
+	multilib_is_native_abi && distutils-r1_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}