Adding metadata

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index 8f903d1da5a9..c94966357fe8 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -1 +1,2 @@
 DIST python-neutronclient-11.0.0.tar.gz 206846 BLAKE2B e7ba4db5763a9310aa393e01d8561e9cfe85dfe584942de70a1b2254ccd8d5a79f6ffe5dc195fc3ef6f338c49686f8460b81111f6d4118315af38d7eea6f8c1c SHA512 3732892db34287343bc7015aa0be426e61f7a111e8a69c529f9baac0b6abbba09232d2d73e255dc82a816a1e9ff70237097c6269a287910a034787af58a730a1
+DIST python-neutronclient-11.1.0.tar.gz 210626 BLAKE2B c9b3328a57fb05a6bd4058b3a96a1a346caea08110724cc5d7d3855d08140bb2baeb3f133464aa02d74a6ed18e3b7f174560766134d15aa681fea68b169c7b2c SHA512 04f81f0dffc085a16ffca76d16c4de7b9c0a686053e45aacbedfb94902651c20dd34c6ccc29b15bb8e8836df5124e466d5f1bea94a82dc06d194fa6c2df62734
diff --git a/dev-python/python-neutronclient/python-neutronclient-11.1.0.ebuild b/dev-python/python-neutronclient/python-neutronclient-11.1.0.ebuild
new file mode 100644
index 000000000000..af5177da0575
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-11.1.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-neutronclient/
+	https://github.com/openstack/python-neutronclient/
+	https://pypi.org/project/python-neutronclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslotest[${PYTHON_USEDEP}]
+		dev-python/python-openstackclient[${PYTHON_USEDEP}]
+		dev-python/subunit[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Needs osprofile
+	rm neutronclient/tests/unit/test_http.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b neutronclient.tests.unit
+}
+
+python_install() {
+	distutils-r1_python_install
+	# stupid stupid stupid
+	local SITEDIR="${D}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.dist-info )
+	[[ -d ${egg[0]} ]] || die "python_quantumclient*.dist-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}