Adding metadata

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/python-manilaclient/python-manilaclient-6.0.0.ebuild b/dev-python/python-manilaclient/python-manilaclient-6.0.0.ebuild
new file mode 100644
index 000000000000..0ebbb18aa4a7
--- /dev/null
+++ b/dev-python/python-manilaclient/python-manilaclient-6.0.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings to the OpenStack Manila API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-manilaclient
+	https://github.com/openstack/python-manilaclient/
+	https://pypi.org/project/python-manilaclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/pbr-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/coverage-4.5.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/stestr-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/tempest-17.1.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/python-openstackclient-5.3.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	# The functional tests would requier the OpenStack manila service to be
+	# packaged, too.
+	eunittest manilaclient/tests/unit
+}