Adding metadata

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.4.ebuild b/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.4.ebuild
new file mode 100644
index 000000000000..3942ab9019ce
--- /dev/null
+++ b/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/python-lsp/python-lsp-ruff
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Ruff linting plugin for the Python LSP Server"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-ruff/
+	https://pypi.org/project/python-lsp-ruff/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-util/ruff-0.8.0
+	dev-python/cattrs[${PYTHON_USEDEP}]
+	dev-python/python-lsp-server[${PYTHON_USEDEP}]
+	>=dev-python/lsprotocol-2023.0.1[${PYTHON_USEDEP}]
+"
+
+EPYTEST_DESELECT=(
+	# Fails due to Gentoofied calling of ruff
+	"tests/test_ruff_lint.py::test_ruff_config_param"
+	"tests/test_ruff_lint.py::test_ruff_settings"
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip Python-level dep on ruff, since we don't install .dist-info
+	sed -i -e '/ruff.*>=/d' pyproject.toml || die
+}