Updating liguros repo

3 files changed, 106 insertions, 1 deletions

diff --git a/dev-python/python-ldap/metadata.xml b/dev-python/python-ldap/metadata.xml
new file mode 100644
index 000000000000..5c901e39ed42
--- /dev/null
+++ b/dev-python/python-ldap/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">python-ldap</remote-id>
+		<remote-id type="github">python-ldap/python-ldap</remote-id>
+		<bugs-to>https://github.com/python-ldap/python-ldap/issues</bugs-to>
+	</upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
diff --git a/dev-python/python-ldap/python-ldap-3.2.0.ebuild b/dev-python/python-ldap/python-ldap-3.2.0.ebuild
index 11ee421f388a..775436269d38 100644
--- a/dev-python/python-ldap/python-ldap-3.2.0.ebuild
+++ b/dev-python/python-ldap/python-ldap-3.2.0.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python2_7 python3_{5,6,7,8,9} )
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
 
 inherit distutils-r1
 
diff --git a/dev-python/python-ldap/python-ldap-9999.ebuild b/dev-python/python-ldap/python-ldap-9999.ebuild
new file mode 100644
index 000000000000..9d3d37a83396
--- /dev/null
+++ b/dev-python/python-ldap/python-ldap-9999.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Various LDAP-related Python modules"
+HOMEPAGE="https://www.python-ldap.org/en/latest/
+	https://pypi.org/project/python-ldap/
+	https://github.com/python-ldap/python-ldap"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/python-ldap/python-ldap.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-solaris"
+fi
+
+LICENSE="PSF-2"
+SLOT="0"
+IUSE="examples sasl ssl"
+
+# We do not need OpenSSL, it is never directly used:
+# https://github.com/python-ldap/python-ldap/issues/224
+RDEPEND="
+	!dev-python/pyldap
+	>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
+	>net-nds/openldap-2.4.11:=[sasl?,ssl?]
+"
+# We do not link against cyrus-sasl but we use some
+# of its headers during the build.
+BDEPEND="
+	>net-nds/openldap-2.4.11:=[sasl?,ssl?]
+	sasl? ( >=dev-libs/cyrus-sasl-2.1 )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx Doc
+
+python_prepare_all() {
+	# The live ebuild won't compile if setuptools_scm < 1.16.2 is installed
+	# https://github.com/pypa/setuptools_scm/issues/228
+	if [[ ${PV} == *9999* ]]; then
+		rm -r .git || die
+	fi
+
+	if ! use sasl; then
+		sed -i 's/HAVE_SASL//g' setup.cfg || die
+	fi
+	if ! use ssl; then
+		sed -i 's/HAVE_TLS//g' setup.cfg || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Run all tests which don't require slapd
+	local ignored_tests=(
+		t_bind.py
+		t_cext.py
+		t_edit.py
+		t_ldapobject.py
+		t_ldap_options.py
+		t_ldap_sasl.py
+		t_ldap_schema_subentry.py
+		t_ldap_syncrepl.py
+		t_slapdobject.py
+	)
+	pushd Tests >/dev/null || die
+	pytest -vv ${ignored_tests[@]/#/--ignore } \
+		|| die "tests failed with ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r Demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}