Adding metadata

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/python-dotenv/python-dotenv-1.2.2.ebuild b/dev-python/python-dotenv/python-dotenv-1.2.2.ebuild
new file mode 100644
index 000000000000..76783e6479ca
--- /dev/null
+++ b/dev-python/python-dotenv/python-dotenv-1.2.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/theskumar/python-dotenv
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Manage .env files"
+HOMEPAGE="
+	https://github.com/theskumar/python-dotenv/
+	https://pypi.org/project/python-dotenv/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/click-5[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o tmp_path_retention_policy=all
+}
+
+python_install() {
+	distutils-r1_python_install
+	ln -s dotenv "${D}$(python_get_scriptdir)"/python-dotenv || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Avoid collision with dev-ruby/dotenv (bug #798648)
+	mv "${ED}"/usr/bin/{,python-}dotenv || die
+}