Adding metadata

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/python-discovery/python-discovery-1.3.0.ebuild b/dev-python/python-discovery/python-discovery-1.3.0.ebuild
new file mode 100644
index 000000000000..b487b66b0704
--- /dev/null
+++ b/dev-python/python-discovery/python-discovery-1.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/python-discovery
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python interpreter discovery"
+HOMEPAGE="
+	https://github.com/tox-dev/python-discovery/
+	https://pypi.org/project/python-discovery/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	>=dev-python/filelock-3.15.4[${PYTHON_USEDEP}]
+	<dev-python/platformdirs-5[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.3.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/setuptools-75.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		python3.*t)
+			EPYTEST_DESELECT+=(
+				# TODO
+				tests/test_py_info_extra.py::test_satisfies_path_not_abs_basename_match
+			)
+			;;
+	esac
+
+	epytest
+}