Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/python-daemon/python-daemon-3.1.2.ebuild b/dev-python/python-daemon/python-daemon-3.1.2.ebuild
new file mode 100644
index 000000000000..00e72c722b52
--- /dev/null
+++ b/dev-python/python-daemon/python-daemon-3.1.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library to implement a well-behaved Unix daemon process"
+HOMEPAGE="
+	https://pagure.io/python-daemon/
+	https://pypi.org/project/python-daemon/
+"
+
+# build system and tests use GPL-3.0+ but none of these files are installed
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~hppa ~mips ~ppc ppc64 ~sparc x86"
+
+RDEPEND="
+	>=dev-python/lockfile-0.10[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	test? (
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# overengineered logic with NIH deps
+	rm setup.py || die
+	cat > setup.cfg <<-EOF || die
+		[metadata]
+		version = ${PV}
+		description = ${DESCRIPTION}
+		maintainer =
+		long_description =
+		exclude = doc
+	EOF
+
+	# tests for their overengineered setup
+	rm test/test_{setup,util_metadata}.py || die
+}