Adding metadata

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/pytest-env/pytest-env-1.7.1.ebuild b/dev-python/pytest-env/pytest-env-1.7.1.ebuild
new file mode 100644
index 000000000000..91585a3371ef
--- /dev/null
+++ b/dev-python/pytest-env/pytest-env-1.7.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/pytest-dev/pytest-env
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="pytest plugin that allows you to add environment variables"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-env/
+	https://pypi.org/project/pytest-env/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/python-dotenv-1.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pytest-9.0.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+}