Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

4 files changed, 96 insertions, 0 deletions

diff --git a/dev-python/pygresql/Manifest b/dev-python/pygresql/Manifest
new file mode 100644
index 000000000000..c39da22bc74e
--- /dev/null
+++ b/dev-python/pygresql/Manifest
@@ -0,0 +1 @@
+DIST pygresql-6.2.3.tar.gz 275395 BLAKE2B 2d709b20664dc3242c340d57b59db81079516ad32e9e7690793b1b15d60a34a417577beb32488c7f293fa0ee4aedcb063224f47aaed98c101a079a69b74e1919 SHA512 80121a2e1a6eceef6f4afda9218f032c7a26a434dd900bad538264cfc8c30d4f18a7e601bae16956cc8977555bc4e8cf7fa9611a39bda4cc20b3b229780ec17f
diff --git a/dev-python/pygresql/files/pygresql-5.2-CFLAGS.patch b/dev-python/pygresql/files/pygresql-5.2-CFLAGS.patch
new file mode 100644
index 000000000000..24b9da21d165
--- /dev/null
+++ b/dev-python/pygresql/files/pygresql-5.2-CFLAGS.patch
@@ -0,0 +1,11 @@
+--- a/setup.py
++++ b/setup.py
+@@ -95,7 +95,7 @@
+ library_dirs = [get_python_lib(), pg_config('libdir')]
+ define_macros = [('PYGRESQL_VERSION', version)]
+ undef_macros = []
+-extra_compile_args = ['-O2', '-funsigned-char', '-Wall', '-Wconversion']
++extra_compile_args = ['-funsigned-char', '-Wall']
+ 
+ 
+ class build_pg_ext(build_ext):
diff --git a/dev-python/pygresql/metadata.xml b/dev-python/pygresql/metadata.xml
new file mode 100644
index 000000000000..5580fe606fcf
--- /dev/null
+++ b/dev-python/pygresql/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>pgsql-bugs@gentoo.org</email>
+		<name>PostgreSQL and Related Package Development</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">PyGreSQL</remote-id>
+		<remote-id type="github">PyGreSQL/PyGreSQL</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/pygresql/pygresql-6.2.3.ebuild b/dev-python/pygresql/pygresql-6.2.3.ebuild
new file mode 100644
index 000000000000..a35b1ed53f71
--- /dev/null
+++ b/dev-python/pygresql/pygresql-6.2.3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN="PyGreSQL"
+POSTGRES_COMPAT=( 9.6 {10..18} )
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 postgres pypi
+
+DESCRIPTION="A Python interface for the PostgreSQL database"
+HOMEPAGE="
+	https://pygresql.github.io/
+	https://github.com/PyGreSQL/PyGreSQL/
+	https://pypi.org/project/PyGreSQL/
+"
+
+LICENSE="POSTGRESQL"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ppc ~sparc x86"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	test? (
+		dev-db/postgresql[server]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.2-CFLAGS.patch
+)
+
+distutils_enable_tests unittest
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		postgres_pkg_setup
+	fi
+}
+
+src_test() {
+	local db="${T}/pgsql"
+	initdb --username=portage -D "${db}" || die
+	pg_ctl -w -D "${db}" start \
+		-o "-h '127.0.0.1' -p 5432 -k '${T}'" || die
+	psql -h "${T}" -U portage -d postgres \
+		-c "ALTER ROLE portage WITH PASSWORD 'postgres';" || die
+	createdb -h "${T}" -U portage test || die
+
+	cat > tests/LOCAL_PyGreSQL.py <<-EOF || die
+		dbhost = '${T}'
+	EOF
+
+	rm -rf pg || die
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${db}" stop || die
+}
+
+python_install_all() {
+	local DOCS=( docs/*.rst docs/community/* docs/contents/tutorial.rst )
+
+	distutils-r1_python_install_all
+}