Adding metadata

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/pygments/pygments-2.20.0.ebuild b/dev-python/pygments/pygments-2.20.0.ebuild
new file mode 100644
index 000000000000..e31bb3041059
--- /dev/null
+++ b/dev-python/pygments/pygments-2.20.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_PN=${PN^}
+PYTHON_FULLY_TESTED=( python3_{12..15} )
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="
+	https://pygments.org/
+	https://github.com/pygments/pygments/
+	https://pypi.org/project/Pygments/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/lxml[${PYTHON_USEDEP}]
+			dev-python/pillow[${PYTHON_USEDEP}]
+		' "${PYTHON_FULLY_TESTED[@]}")
+		dev-python/wcag-contrast-ratio[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+	)
+"
+
+EPYTEST_DESELECT=(
+	# fuzzing tests, very slow
+	tests/test_basic_api.py::test_random_input
+)
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp external/pygments.bashcomp pygmentize
+}