Adding metadata

3 files changed, 104 insertions, 0 deletions

diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
new file mode 100644
index 000000000000..9a3f91f37db7
--- /dev/null
+++ b/dev-python/pyglet/Manifest
@@ -0,0 +1 @@
+DIST pyglet-2.1.14.tar.gz 6595146 BLAKE2B 1a2b59b61183eab83362af9f2eedf9267c64b287d8b1601557abe18660ce078181169e7d4c7378367d87f653a0f6721b8ece71eb818742753a5823f481af9ea3 SHA512 f9a219d9e49268bfd7f8979e037e779f243f2576ea57553d1ef1ccce72f1d9d5b1c791fc29d3faad7abc59855e366e2e51d3a0e0e646fcd8804def5a2d3fd519
diff --git a/dev-python/pyglet/metadata.xml b/dev-python/pyglet/metadata.xml
new file mode 100644
index 000000000000..24cd9d6100f6
--- /dev/null
+++ b/dev-python/pyglet/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <use>
+    <flag name="image">Enable support for image formats other than PNG and BMP</flag>
+  </use>
+  <longdescription lang="en">This library provides an object-oriented programming interface
+  for developing games and other visually-rich applications with Python.
+  pyglet has virtually no external dependencies. For most applications
+  and game requirements, pyglet needs nothing else besides Python,
+  simplifying distribution and installation. It also handles
+  multiple windows and fully aware of multi-monitor setups.
+  pyglet might be seen as an alternative to PyGame.</longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pyglet/pyglet-2.1.14.ebuild b/dev-python/pyglet/pyglet-2.1.14.ebuild
new file mode 100644
index 000000000000..05f3a41045cc
--- /dev/null
+++ b/dev-python/pyglet/pyglet-2.1.14.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi virtualx xdg-utils
+
+MY_P=${P/_/.}
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="
+	https://pyglet.org/
+	https://github.com/pyglet/pyglet/
+	https://pypi.org/project/pyglet/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
+IUSE="examples image +sound"
+
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? (
+		|| (
+			dev-python/pillow[${PYTHON_USEDEP}]
+			x11-libs/gtk+:2
+		)
+	)
+	sound? (
+		|| (
+			media-libs/libpulse
+			media-libs/openal
+		)
+	)
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/fontconfig
+		x11-base/xorg-server[-minimal]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	local EPYTEST_DESELECT=(
+		# lacking device/server permissions
+		tests/unit/media/test_listener.py::test_openal_listener
+		tests/unit/media/test_listener.py::test_pulse_listener
+		# fragile to system load
+		tests/unit/media/test_player.py::PlayerTestCase::test_pause_resume
+		tests/unit/test_clock_freq.py::test_elapsed_time_between_tick
+	)
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	nonfatal epytest tests/unit || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}