Adding metadata

3 files changed, 1 insertions, 94 deletions

diff --git a/dev-python/pydevd/Manifest b/dev-python/pydevd/Manifest
index be5b85af2bcc..aae4c501a8cd 100644
--- a/dev-python/pydevd/Manifest
+++ b/dev-python/pydevd/Manifest
@@ -1,2 +1 @@
-DIST pydevd-2.9.3.gh.tar.gz 3979334 BLAKE2B f26af62d12d89317ffc9e670c78bac2c977195897dfb858861f6d12a331714c084d11dc030efe82777d51f9cd429b54d78c7126f366fdda15ebd315121b55dcd SHA512 c8d30658e84a1edd3e4d0cd35563f50231b6a2df247fecab5e90236c4c80da10e7fe5f182b1791f86063d3228d115d32d388087605e58842505ab19aabe75444
 DIST pydevd-2.9.5.gh.tar.gz 3982897 BLAKE2B 06f0712301b419c472bcef2443a2ed277eb477041ff2e40e41b57f61649d84a7559dcae82c30ac572b14e90b98c2b9b9542c7360deded087eec92aeb0372ad67 SHA512 9aa38bc9a238e6f2956883a6318536382726013ea9e4a9d902b36d60df0cf924c279545bcdf92afdb435bfe36598982edd5805725860798fb3970b105254ba1d
diff --git a/dev-python/pydevd/pydevd-2.9.3.ebuild b/dev-python/pydevd/pydevd-2.9.3.ebuild
deleted file mode 100644
index 5edc970f883a..000000000000
--- a/dev-python/pydevd/pydevd-2.9.3.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
-inherit distutils-r1 toolchain-funcs
-
-MY_P="pydev_debugger_${PV//./_}"
-
-DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
-HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
-SRC_URI="
-	https://github.com/fabioz/PyDev.Debugger/archive/${MY_P}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-S="${WORKDIR}/PyDev.Debugger-${MY_P}"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-
-# After removing and recompiling the prebuilt lib the tests fail?
-# For some reason the test suite is executing a slightly different gdb command
-# then before, which is lacking the file name of the lib that was pre built:
-# gdb: No symbol table is loaded. Use the "file" command
-# This also happens outside of portage so it is not related to any *FLAGS
-RESTRICT="test"
-
-BDEPEND="
-	test? (
-		dev-python/untangle[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-	)
-"
-
-# Block against the version of debugpy that still bundles pydevd
-RDEPEND="
-	!<dev-python/debugpy-1.4.2
-	sys-devel/gdb
-"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# Drop -O3 and -flto compiler args
-	sed -i \
-		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
-		-e '/extra_compile_args/d' \
-		setup.py || die
-
-	# Clean up some prebuilt files
-	rm -r third_party || die
-	cd pydevd_attach_to_process || die
-
-	# Remove these Windows files
-	rm attach_{amd64,x86}.dll || die
-	rm inject_dll_{amd64,x86}.exe || die
-	rm run_code_on_dllmain_{amd64,x86}.dll || die
-	rm -r windows winappdbg || die
-
-	# Remove these MacOS files
-	rm attach_x86_64.dylib || die
-
-	# Remove these prebuilt linux files
-	rm attach_linux_{amd64,x86}.so || die
-
-	cd linux_and_mac || die
-	rm compile_mac.sh || die
-}
-
-src_compile() {
-	pushd pydevd_attach_to_process/linux_and_mac || die
-	# recompile removed file (extracted from compile_linux.sh)
-	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} -o "attach_linux_${ARCH}.so" \
-		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
-	mv "attach_linux_${ARCH}.so" ../ || die
-	popd || die
-
-	distutils-r1_src_compile
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	# Remove this duplicate that is installed directly to /usr/
-	# These files are also correctly installed to the python site-packages dir
-	rm -r "${ED}/usr/pydevd_attach_to_process" || die
-}
diff --git a/dev-python/pydevd/pydevd-2.9.5.ebuild b/dev-python/pydevd/pydevd-2.9.5.ebuild
index 6a709f34d050..c6c33a92c34d 100644
--- a/dev-python/pydevd/pydevd-2.9.5.ebuild
+++ b/dev-python/pydevd/pydevd-2.9.5.ebuild
@@ -19,7 +19,7 @@ S="${WORKDIR}/PyDev.Debugger-${MY_P}"
 
 LICENSE="EPL-1.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 # After removing and recompiling the prebuilt lib the tests fail?
 # For some reason the test suite is executing a slightly different gdb command