Adding metadata

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/polygon/polygon-3.0.7-r1.ebuild b/dev-python/polygon/polygon-3.0.7-r1.ebuild
new file mode 100644
index 000000000000..c14b13abc226
--- /dev/null
+++ b/dev-python/polygon/polygon-3.0.7-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python package to handle polygonal shapes in 2D"
+HOMEPAGE="https://www.j-raedler.de/projects/polygon/"
+SRC_URI="https://www.bitbucket.org/jraedler/${PN}3/downloads/Polygon3-${PV}.zip"
+S="${WORKDIR}/Polygon3-${PV}"
+
+LICENSE="LGPL-2"
+SLOT="3"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="examples"
+
+BDEPEND="app-arch/unzip"
+
+DOCS=( doc/{Polygon.txt,Polygon.pdf} )
+
+python_prepare_all() {
+	if use examples; then
+		mkdir examples || die
+		mv doc/{Examples.py,testpoly.gpf} examples || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" test/Test.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}