Adding metadata

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index f4d8f3659995..c7b09016c7dc 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1 +1,2 @@
 DIST plotly.py-6.7.0.gh.tar.gz 10364351 BLAKE2B 335dcabc60048651d6e356bbb59320977989be15d5ea33d03e6ff2b2f5c19d0774679fccbe7da442287ee1dd94cfba14beb2f40fd538f13ffde3acf56839346a SHA512 ad651e9a79be30bb9123f2fd26d8847eba7cc7168924af5237c495352749bebd12c823e5294865ad9aca69ccaeb4636baa1f82b4bcc39b747a02b9b58c52da5d
+DIST plotly.py-6.8.0.gh.tar.gz 10539690 BLAKE2B d76f29669cc393bc8e842a95182f876b15d869cf75dff6ecdd7c4bc01de2239f6d3bcecf2e2a29171fead59e1cbac38820caa7ad9632b3b8d9fda4cbba528be0 SHA512 8be8a6f2cd6ba94bc18130524853679ce8f58d3b220eed06e508dc147209e94df51da68a9b8934288caddcbdf82ef93c3b50ad9c563a7298726383634c7e5ec4
diff --git a/dev-python/plotly/plotly-6.8.0.ebuild b/dev-python/plotly/plotly-6.8.0.ebuild
new file mode 100644
index 000000000000..8e0e8fb4c131
--- /dev/null
+++ b/dev-python/plotly/plotly-6.8.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV/_}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/narwhals-1.15.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/scikit-image[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+
+EPYTEST_PLUGINS=()
+# xdist is causing pretty nasty race conditions here
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# requires polars
+	tests/test_optional/test_px
+
+	# requires kaleido
+	tests/test_optional/test_kaleido/test_kaleido.py
+)
+
+EPYTEST_DESELECT=(
+	# requires polars
+	'tests/test_plotly_utils/validators/test_fig_deepcopy.py::test_deepcopy_dataframe[polars]'
+
+	# require anywidgets
+	'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget1]'
+
+	# minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# fails in non-isolated env
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# TODO
+	'tests/test_plotly_utils/validators/test_colorscale_validator.py::test_acceptance_named[Inferno_r]'
+
+	# numpy 2.4
+	tests/test_optional/test_figure_factory/test_figure_factory.py::TestViolin::test_violin_fig
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_encode_customdata_datetime_homogeneous_dataframe
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_encode_customdata_datetime_series
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_numpy_datetime64
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# stop installing junk "js" package
+	sed -i -e '/used by Jupyter extension/d' pyproject.toml || die
+}
+
+src_configure() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+}