Adding metadata

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index ccc0041d8459..caa2d6cdc46d 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
 DIST pdm-2.27.0.tar.gz 2686064 BLAKE2B 4b970f08091548e2e5597f56f3cbf1e61b8ff941b96a3c28523c76a6c80dc9a4496c815f2b3f9bd50975ccb18912f84fc23b9e6a5e77c7b283901197e1ccc011 SHA512 f3828367a641bc9f9427d6348092bf92f6da73198dd41294c3e9c8de0108fd97d3388d887df69146f4474c3d48a79f36f41d7aad1f442b5d8eb69263646ced37
+DIST pdm-2.28.0.tar.gz 2693556 BLAKE2B 369e7030dead4dca288cf455b20105a002a67f2a0f1856d13c52cac8e0ba723c78b9ae1865e6842fcc62ca62a39d2f88c58168d514ec849468a6e0b9dab9aa86 SHA512 eca6bbfc3de04a98636b316c5fb23a44b41a07563b5b5d638a5bd7d0cf8671695b4ec18629dd3960651fd02759db88037ab04fa68206f6f19710116b01ef29f0
diff --git a/dev-python/pdm/pdm-2.28.0.ebuild b/dev-python/pdm/pdm-2.28.0.ebuild
new file mode 100644
index 000000000000..1527b61e5c9e
--- /dev/null
+++ b/dev-python/pdm/pdm-2.28.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/installer-1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.10.07[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+	# remove pkgutil namespace magic, as it doesn't work and makes
+	# dev-python/pdm-backend tests test the wrong package
+	rm src/pdm/__init__.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+		# TODO: random regression?
+		tests/cli/test_python.py::test_find_python
+		# TODO
+		tests/test_formats.py::test_export_from_pylock_not_empty
+	)
+
+	epytest -m "not network and not integration and not path"
+}