Adding metadata

3 files changed, 89 insertions, 0 deletions

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
new file mode 100644
index 000000000000..7ef7ed1f3a5d
--- /dev/null
+++ b/dev-python/pdm-backend/Manifest
@@ -0,0 +1 @@
+DIST pdm-backend-2.4.8.gh.tar.gz 159228 BLAKE2B ddba89eab214262813cbe003f2793a5cd8edf03cf0650b7b4a625d2b6e54233cb63bd06e5f8ed4a47ca061e68d796d509555d53657fbb64b34ceaf2d48cf047c SHA512 ba5ff3926b3dfaa194b9faa2bb3727343aa36f28a60d5a33dc39d822900c0c650a39c34338c95f4c8ffaf1736aac24a215812ff5ea2c58e3e68cf2d431826c79
diff --git a/dev-python/pdm-backend/metadata.xml b/dev-python/pdm-backend/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/pdm-backend/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild b/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild
new file mode 100644
index 000000000000..4207b40b2fbc
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/editables-0.5[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.9.0_beta7[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# changes in editables or somewhere
+	tests/test_api.py::test_build_editable
+	tests/test_api.py::test_build_editable_src
+	tests/test_api.py::test_build_editable_pep420
+)
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	epytest -k "not [hg"
+}