Adding metadata

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index f5aaf7f2c181..6b2debbca949 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.3.0.gh.tar.gz 134657 BLAKE2B 346011ed97111e54c9cd063e216aa5943e6dd5ac1e531ceed225bf07420d07131aca0d6c23d24c0ba11e2e4a8c581b8c1cb1c8b7efa9c7a030d48ba982264dce SHA512 0169b97b662a0520c9810d566b74b6ef378db083954064ee37e8ed8cc40375a556500c307cebb9e269c3192b9f9b8659f575f0d24d67f970b3797e2354b53d54
+DIST pdm-backend-2.3.1.gh.tar.gz 136710 BLAKE2B 72293989700a429bfddb1d865b14f0467d56e024d69976264909d1c5113be67fd6892f3821803b6e86d73653f54a62b15ccb02f3dc16a190f6ccd0ca5e0650b5 SHA512 6a1a4d45a95b08f0a06f54635224c6faabc000384f489eb1e462d7dfffdd9899a3040a0fb708d193b3da541e2704b30921185728a178517fa55ecf3314f9903d
diff --git a/dev-python/pdm-backend/pdm-backend-2.3.1.ebuild b/dev-python/pdm-backend/pdm-backend-2.3.1.ebuild
new file mode 100644
index 000000000000..4cfb39e7b26d
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.3.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/editables-0.5[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -k "not [hg"
+}