Adding metadata

4 files changed, 175 insertions, 0 deletions

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
new file mode 100644
index 000000000000..694e9deb1137
--- /dev/null
+++ b/dev-python/pbr/Manifest
@@ -0,0 +1 @@
+DIST pbr-7.0.3.tar.gz 135625 BLAKE2B a0271614d745165056a65d6de3673217fe4ae2d3bbc43b0eb7b9d1b07fef4364dc3e5f938ce0db63b9fb5031247a49ccca1be4bbee5ecbc4d53ca6663faaaba1 SHA512 dff6c9ae44cdb8db111d87530a1096dd3f9045df20cb3105f736b909f9dce957e2e8f54d6a8a1c09139689d39b1b3b4dbd53947414e4d467b11314b7f397fb99
diff --git a/dev-python/pbr/metadata.xml b/dev-python/pbr/metadata.xml
new file mode 100644
index 000000000000..e11e5d11fa1c
--- /dev/null
+++ b/dev-python/pbr/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>prometheanfire@gentoo.org</email>
+    <name>Matthew Thode</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>openstack@gentoo.org</email>
+    <name>Openstack</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    Python Build Reasonableness
+  PBR is a library that injects some useful and sensible default behaviors into your setuptools run.
+  </longdescription>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pbr/pbr-7.0.3-r1.ebuild b/dev-python/pbr/pbr-7.0.3-r1.ebuild
new file mode 100644
index 000000000000..1a48791d56e9
--- /dev/null
+++ b/dev-python/pbr/pbr-7.0.3-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{13..14} )
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+# importlib-resources/pkg-resources: _compat/metadata.py
+# packaging/pkg-resources: _compat/packaging.py
+RDEPEND="
+	|| (
+		dev-python/importlib-resources[${PYTHON_USEDEP}]
+		dev-python/pkg-resources[${PYTHON_USEDEP}]
+	)
+	|| (
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+		dev-python/pkg-resources[${PYTHON_USEDEP}]
+	)
+	>=dev-python/setuptools-64.0.0[${PYTHON_USEDEP}]
+"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and
+# https://bugs.gentoo.org/show_bug.cgi?id=561038 docutils is needed for sphinx
+# exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848 stestr is run as
+# external tool.
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_with_argument:_&:' \
+		-e 's:test_wsgi_script_run:_&:' \
+		-i pbr/tests/functional/test_wsgi_scripts.py || die
+	# installs random packages via pip from the Internet
+	rm pbr/tests/functional/test_pep517.py || die
+	rm pbr/tests/functional/test_requirements.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest -b
+}
diff --git a/dev-python/pbr/pbr-7.0.3-r2.ebuild b/dev-python/pbr/pbr-7.0.3-r2.ebuild
new file mode 100644
index 000000000000..4f449b2e2167
--- /dev/null
+++ b/dev-python/pbr/pbr-7.0.3-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{13..14} )
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib-resources[${PYTHON_USEDEP}]
+	' pypy3_11 3.11)
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-64.0.0[${PYTHON_USEDEP}]
+"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and
+# https://bugs.gentoo.org/show_bug.cgi?id=561038 docutils is needed for sphinx
+# exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848 stestr is run as
+# external tool.
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_with_argument:_&:' \
+		-e 's:test_wsgi_script_run:_&:' \
+		-i pbr/tests/functional/test_wsgi_scripts.py || die
+	# installs random packages via pip from the Internet
+	rm pbr/tests/functional/test_pep517.py || die
+	rm pbr/tests/functional/test_requirements.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest -b
+}