Adding metadata

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.43.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.43.0.ebuild
new file mode 100644
index 000000000000..3ddcf7f2567a
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.43.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest
+}