Adding metadata

2 files changed, 97 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 3a8729c087ab..911a4c96f5f2 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1,2 +1,3 @@
+DIST openstacksdk-4.10.0.tar.gz 1319494 BLAKE2B ad38f63d626c904bd0f2e61216a12a6291be24a8d20de2db8c0092620e41592cab4afb28281c212319ac285cbc62a330f136560eee9a031166ac687786d4fd67 SHA512 2a0b13884625662c09e5a60626fbd9a12c53157c69039a8936370d4ad3e675fcaa02a6f472e75568e18e95cd9c36f3c41b5d31468dc48af84cb32b2a240252b9
 DIST openstacksdk-4.8.0.tar.gz 1309981 BLAKE2B 41b047b7e120c72cec8555daa7910870ca6f3ca56a14865e5f684d0754500728fc38974a25664b4aecb21bf37e5b06fdd8755dc13a88bbaa0fe4830903dc1db9 SHA512 993476e818648244c091f3b26bf9d532346859014de353bf45869531325c0c67ac66d1493be38c02389f51991c134ea87342ce89cc57073a8b9f62e606f108f1
 DIST openstacksdk-4.9.0.tar.gz 1316550 BLAKE2B af03d1db2c0cfaeb00831f4c9b5dadb6bd3947cad3b13d5d942a648dc56f93438c60f8ea95fe073380f0b5c2d2f66f9172b98ca526ce10f7a9bf18a421140ba3 SHA512 71c30844ce2db587b561cc4baa3231056dc91313e110618c4d2de5ed2ecb919eff98a0387bd83edc8441b45322009a61dd9038374e641b52432e13e47ea315aa
diff --git a/dev-python/openstacksdk/openstacksdk-4.10.0.ebuild b/dev-python/openstacksdk/openstacksdk-4.10.0.ebuild
new file mode 100644
index 000000000000..18398b222280
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-4.10.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.21[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-5.10.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus-client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.12.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+	sed -e 's:test_servers:_&:' \
+		-i openstack/tests/unit/test_stats.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	# fragile warning-based tests
+	sed -e 's:test_unsupported_version_override:_&:' \
+		-i openstack/tests/unit/test_missing_version.py || die
+	sed -e 's:test_create_unknown_proxy:_&:' \
+		-i openstack/tests/unit/test_connection.py || die
+
+	# stupid test checking if they pin to the newest os-service-types,
+	# except they don't actually do
+	sed -e 's:test_ost_version:_&:' \
+		-i openstack/tests/unit/test_utils.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}