Adding metadata

1 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/openapi-core/openapi-core-0.23.1-r2.ebuild b/dev-python/openapi-core/openapi-core-0.23.1-r2.ebuild
new file mode 100644
index 000000000000..1944b382e790
--- /dev/null
+++ b/dev-python/openapi-core/openapi-core-0.23.1-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry-core
+PYPI_VERIFY_REPO=https://github.com/python-openapi/openapi-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Client-side and server-side support for the OpenAPI Specification v3"
+HOMEPAGE="
+	https://github.com/python-openapi/openapi-core/
+	https://pypi.org/project/openapi-core/
+"
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *_beta* ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+	dev-python/isodate[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
+	=dev-python/jsonschema-path-0.5*[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	=dev-python/openapi-schema-validator-0.9*[${PYTHON_USEDEP}]
+	=dev-python/openapi-spec-validator-0.9*[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-2.1.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/aiohttp-3.8.4[${PYTHON_USEDEP}]
+		>=dev-python/aioitertools-0.11.0[${PYTHON_USEDEP}]
+		>=dev-python/django-4.0[${PYTHON_USEDEP}]
+		dev-python/djangorestframework[${PYTHON_USEDEP}]
+		>=dev-python/flask-2.0[${PYTHON_USEDEP}]
+		>=dev-python/httpx-0.24.0[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/starlette-0.40.0[${PYTHON_USEDEP}]
+		dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+		dev-python/webob[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{aiohttp,asyncio} )
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/python-openapi/openapi-core/commit/080936641de41f2ba533f3ce02832be14330686b
+	"${FILESDIR}/${P}-deps.patch"
+)
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# missing dependencies
+		tests/integration/contrib/falcon
+		tests/integration/contrib/fastapi
+
+		# TODO: these tests fail to collect
+		tests/integration/validation/test_security_override.py
+		tests/integration/validation/test_read_only_write_only.py
+	)
+
+	epytest -o addopts=
+}