Adding metadataHEADdevelop

3 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/numexpr/Manifest b/dev-python/numexpr/Manifest
new file mode 100644
index 000000000000..09349fdb83cd
--- /dev/null
+++ b/dev-python/numexpr/Manifest
@@ -0,0 +1 @@
+DIST numexpr-2.14.1.gh.tar.gz 134417 BLAKE2B 88f010494404fa3149ac1b523e00d33013fa1ee0dadd672233eacc659818995edd2c151e1c89934fa6ce2695161e7a2ba182bb6ab5b6e020438f27cd4b27f975 SHA512 1bc50ce9f676d68d132a3e7bcded4b1f3feef2a9b43dce730bceb7999dc308d70700cffe45261d18128e0c0efbab574996ff33ac353915b59308d0da55761415
diff --git a/dev-python/numexpr/metadata.xml b/dev-python/numexpr/metadata.xml
new file mode 100644
index 000000000000..99321376cf14
--- /dev/null
+++ b/dev-python/numexpr/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription lang="en">
+  The numexpr package evaluates multiple-operator array expressions
+  many times faster than NumPy can. It accepts the expression as a
+  string, analyzes it, rewrites it more efficiently, and compiles it
+  to faster Python code on the fly. It's the next best thing to
+  writing the expression in C and compiling it with a specialized
+  just-in-time (JIT) compiler, i.e. it does not require a compiler at
+  runtime.
+  </longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/numexpr/numexpr-2.14.1.ebuild b/dev-python/numexpr/numexpr-2.14.1.ebuild
new file mode 100644
index 000000000000..87df94d6f16f
--- /dev/null
+++ b/dev-python/numexpr/numexpr-2.14.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Fast numerical array expression evaluator for Python and NumPy"
+HOMEPAGE="
+	https://github.com/pydata/numexpr/
+	https://pypi.org/project/numexpr/
+"
+SRC_URI="
+	https://github.com/pydata/numexpr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+
+DEPEND="
+	>=dev-python/numpy-2.0.0:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	# Tests will test that these variables are "safely" parsed, and break
+	# if you set them yourself. They don't do any real work, just asserts.
+	# Bug 963118.
+	unset NUMEXPR_MAX_THREADS NUMEXPR_NUM_THREADS OMP_NUM_THREADS
+
+	pushd "${BUILD_DIR}/install/$(python_get_sitedir)" >/dev/null || die
+	"${EPYTHON}" -c '
+import sys,numexpr
+sys.exit(0 if numexpr.test(verbosity=2).wasSuccessful() else 1)
+	' || die "Tests failed with ${EPYTHON}"
+	pushd >/dev/null || die
+}