Updating liguros repo

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/numexpr/numexpr-2.7.2.ebuild b/dev-python/numexpr/numexpr-2.7.2.ebuild
new file mode 100644
index 000000000000..1402b78693e3
--- /dev/null
+++ b/dev-python/numexpr/numexpr-2.7.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Fast numerical array expression evaluator for Python and NumPy"
+HOMEPAGE="https://github.com/pydata/numexpr"
+SRC_URI="
+	https://github.com/pydata/numexpr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="mkl"
+
+RDEPEND="
+	>=dev-python/numpy-1.6[${PYTHON_USEDEP}]
+	mkl? ( sci-libs/mkl )
+"
+
+python_prepare_all() {
+	# TODO: mkl can be used but it fails for me
+	# only works with mkl in tree. newer mkl will use pkgconfig
+	if use mkl; then
+		use amd64 && local ext="_lp64"
+		cat > site.cfg <<- _EOF_ || die
+			[mkl]
+			library_dirs = ${MKLROOT}/lib/em64t
+			include_dirs = ${MKLROOT}/include
+			mkl_libs = mkl_solver${ext}, mkl_intel${ext}, \
+			mkl_intel_thread, mkl_core, iomp5
+		_EOF_
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" \
+		-c "import sys,numexpr; sys.exit(0 if numexpr.test().wasSuccessful() else 1)" \
+		|| die
+	pushd >/dev/null || die
+}