Adding metadata

3 files changed, 98 insertions, 0 deletions

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
new file mode 100644
index 000000000000..6c2e94a1e918
--- /dev/null
+++ b/dev-python/nbconvert/Manifest
@@ -0,0 +1 @@
+DIST nbconvert-7.17.1.tar.gz 865311 BLAKE2B 19e8b78b04778da31b6c14915e8ccc6aeb5406f4388f5239d4431fc175438aae6b1f1d273003c60cfbe168880d036338c219949f379c69b85432025448afc5a2 SHA512 d6f5db5707a60388e4ba9c3b59aa8e1d43394f49cfc18434d649c6b7bd755a2752c12ab224b0a487dd240191b11b691fbcc41cd2a956db2e33db6314fa2d104e
diff --git a/dev-python/nbconvert/metadata.xml b/dev-python/nbconvert/metadata.xml
new file mode 100644
index 000000000000..ce5b0fbfd505
--- /dev/null
+++ b/dev-python/nbconvert/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <upstream>
+    <remote-id type="cpe">cpe:/a:jupyter:nbconvert</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/nbconvert/nbconvert-7.17.1.ebuild b/dev-python/nbconvert/nbconvert-7.17.1.ebuild
new file mode 100644
index 000000000000..6be104a956b5
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-7.17.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="
+	https://nbconvert.readthedocs.io/
+	https://github.com/jupyter/nbconvert/
+	https://pypi.org/project/nbconvert/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.7[${PYTHON_USEDEP}]
+	dev-python/jupyterlab-pygments[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.0[${PYTHON_USEDEP}]
+	<dev-python/mistune-4[${PYTHON_USEDEP}]
+	>=dev-python/nbclient-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.7[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+"
+# via bleach[css]
+RDEPEND+="
+	dev-python/tinycss2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-7.5[${PYTHON_USEDEP}]
+	)
+"
+
+# tests/preprocessors/test_execute.py are extremely flaky over output
+# buffering
+EPYTEST_PLUGINS=( flaky )
+EPYTEST_RERUNS=10
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_nbconvertapp.py::TestNbConvertApp::test_convert_full_qualified_name
+		tests/test_nbconvertapp.py::TestNbConvertApp::test_post_processor
+		# crazy qtweb* stuff, perhaps permissions
+		tests/exporters/test_qtpdf.py::TestQtPDFExporter::test_export
+		tests/exporters/test_qtpng.py::TestQtPNGExporter::test_export
+	)
+
+	# virtx implies nonfatal, make it explicit to avoid confusion
+	nonfatal epytest || die
+}
+
+pkg_postinst() {
+	if ! has_version virtual/pandoc; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc or app-text/pandoc-bin."
+	fi
+}