Adding metadata

3 files changed, 103 insertions, 0 deletions

diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
new file mode 100644
index 000000000000..41230a7b14d7
--- /dev/null
+++ b/dev-python/nbclassic/Manifest
@@ -0,0 +1 @@
+DIST nbclassic-1.3.3.tar.gz 64116062 BLAKE2B b7a8022fe4a9c0729edfa78bde9b84017a9c4768794da3f9c85b4f3266d9a81867d8486ac50dc2ab9cabf3721dc12d6776c00d9b827b6e353dbce80616eb4d2c SHA512 c973702164bc8ffc5b0e0bddd94b4ec93b12d1ab0aab25263be84e1111fedc671e2007e8c31a410ea037fb69ec8318b783c2504632545355580a48fdbe31e00d
diff --git a/dev-python/nbclassic/metadata.xml b/dev-python/nbclassic/metadata.xml
new file mode 100644
index 000000000000..b79a884f5527
--- /dev/null
+++ b/dev-python/nbclassic/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/nbclassic/nbclassic-1.3.3.ebuild b/dev-python/nbclassic/nbclassic-1.3.3.ebuild
new file mode 100644
index 000000000000..4d639fe174e6
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-1.3.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbclassic/
+	https://pypi.org/project/nbclassic/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv x86"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython-genutils[${PYTHON_USEDEP}]
+	>=dev-python/nest-asyncio-1.5[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/babel
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		virtual/pandoc
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{jupyter,tornasync} )
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/pydata-sphinx-theme \
+	dev-python/nbsphinx \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/myst-parser \
+	dev-python/ipython-genutils
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Confuses hatchling sometimes, resulting in partial install.
+	# https://github.com/jupyter/nbclassic/issues/336
+	rm .gitignore || die
+
+	# Let's save some space at build-time, we're not using them anyway.
+	rm -r node_modules || die
+
+	# Dead symlinks that trip up hatchling sometimes, depending
+	# on the phase of the moon.
+	rm -r nbclassic/static/components/*/node_modules || die
+}
+
+python_test() {
+	# Notebook interferes with our tests, pretend it does not exist
+	echo "raise ImportError" > notebook.py || die
+
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}