Adding metadata

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
index 7b769c3d9cda..c58d147685f4 100644
--- a/dev-python/nbclassic/Manifest
+++ b/dev-python/nbclassic/Manifest
@@ -1 +1,2 @@
 DIST nbclassic-0.4.8.tar.gz 19875247 BLAKE2B f6a4ff226ebd7c39fa657e06c1854e24ef7e50e893cc1a0b52c0cef194f8638b26a3b4a74d6d4077c055470bf1a7895995e184f3678b1157813981223631f6a6 SHA512 a0b6cc7823da3e7bd3ae7627994fd6a0e79adcc201763e6597e41d0f2a1fe287edb38903e4240702a34e20bd5e3c32c5460ca3b3355f59585bd2aa8dc46276f2
+DIST nbclassic-0.5.1.tar.gz 20178622 BLAKE2B 1ff79c9af218011c697016ecef149f42e683607eebb8e199ef75957d9d3127858ce8f443aeedb60844e3277b4c8cd4959d123658a5103ab2112fec469ef01a96 SHA512 1dabc27ad115d1961e7881e7a51653449cae291c74aea222bbf92d49cb7bc9657ae1f1d9a81eafbd70bc0cafd57b75cd2c76bebf91aabc5fdd9eede534f1cec9
diff --git a/dev-python/nbclassic/nbclassic-0.5.1.ebuild b/dev-python/nbclassic/nbclassic-0.5.1.ebuild
new file mode 100644
index 000000000000..e1253e28c7fb
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-0.5.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=jupyter
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbclassic/
+	https://pypi.org/project/nbclassic/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_server-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-5[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nest_asyncio-1.5[${PYTHON_USEDEP}]
+	>=dev-python/notebook_shim-0.1.0[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/send2trash-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+
+	<dev-python/notebook-7[${PYTHON_USEDEP}]
+"
+
+# dev-python/nbval is missing impls
+BDEPEND="
+	test? (
+		dev-python/pytest_jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		virtual/pandoc
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx_rtd_theme \
+	dev-python/nbsphinx \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/myst_parser \
+	dev-python/ipython_genutils
+
+EPYTEST_DESELECT=(
+	# TODO: package jupyter_server_terminals
+	tests/test_notebookapp.py::test_tree_handler
+	tests/test_notebookapp.py::test_terminal_handler
+)
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_tornasync.plugin
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}