Adding metadata

2 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
index a78580fe2490..3f10efab1f2c 100644
--- a/dev-python/nbclassic/Manifest
+++ b/dev-python/nbclassic/Manifest
@@ -1 +1,2 @@
 DIST nbclassic-1.3.1.tar.gz 81488343 BLAKE2B c10a1feb4a6987c163f8e8356fd80fe6be9e4958950e748e0bfd8ed1772237b909cbea623f01c052389f8721d6a2b7e710a907e91fe5c67b14197bf1a4f1b8c5 SHA512 9c9b45d15c68587e2147f50615b814106505f68a3255539769a78826c63abb85bd9e4b89ee663be609c210e904e9fd34a18a27687526753f9c06a726b6446f0e
+DIST nbclassic-1.3.2.tar.gz 63500110 BLAKE2B 755875fa142ce084c1d8525ec0ae607bc9b9de40298949e40ed1c93390de7c113f988355d67b34da9f0c170654f639b32907fd6fb623c0112622259ba0f0034b SHA512 4c090cf518616d2b485b00c63fe2d2a4c11418e58b4582eed15b84695997ba05181a09042c17482301f53423d84ffc4fceb847a697ccd9a77882e96c73cf1df5
diff --git a/dev-python/nbclassic/nbclassic-1.3.2.ebuild b/dev-python/nbclassic/nbclassic-1.3.2.ebuild
new file mode 100644
index 000000000000..22abf0ffaa96
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-1.3.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbclassic/
+	https://pypi.org/project/nbclassic/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython-genutils[${PYTHON_USEDEP}]
+	>=dev-python/nest-asyncio-1.5[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		virtual/pandoc
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{jupyter,tornasync} )
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/pydata-sphinx-theme \
+	dev-python/nbsphinx \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/myst-parser \
+	dev-python/ipython-genutils
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Confuses hatchling sometimes, resulting in partial install.
+	# https://github.com/jupyter/nbclassic/issues/336
+	rm .gitignore || die
+
+	# Let's save some space at build-time, we're not using them anyway.
+	rm -r node_modules || die
+
+	# Dead symlinks that trip up hatchling sometimes, depending
+	# on the phase of the moon.
+	rm -r nbclassic/static/components/*/node_modules || die
+}
+
+python_test() {
+	# Notebook interferes with our tests, pretend it does not exist
+	echo "raise ImportError" > notebook.py || die
+
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}