Adding metadata

3 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/multidict/Manifest b/dev-python/multidict/Manifest
new file mode 100644
index 000000000000..d9edaf612cc2
--- /dev/null
+++ b/dev-python/multidict/Manifest
@@ -0,0 +1 @@
+DIST multidict-6.7.1.gh.tar.gz 120010 BLAKE2B db03d9be850b3d2b042ecaa5484fd692fdb47a626862b57e2b218beeba90ae7b12a5e204bd3fdf20a4a125abf1dffb88c52cfc449c0daa31cfed585a74782a3f SHA512 4009a310dac4732c48cc9654fbd55468dda5a6d18a05ef013ff90b030d3124459620d6d6ae4f85e88ef6cefa0b9bccea1b745f3acbfa0b351eb2c92cc8812b89
diff --git a/dev-python/multidict/metadata.xml b/dev-python/multidict/metadata.xml
new file mode 100644
index 000000000000..ca585e83e68d
--- /dev/null
+++ b/dev-python/multidict/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <use>
+    <flag name="native-extensions">
+			Compile native C extensions (speedups, instead of using Python
+			fallback code).
+		</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/multidict/multidict-6.7.1.ebuild b/dev-python/multidict/multidict-6.7.1.ebuild
new file mode 100644
index 000000000000..69431213438c
--- /dev/null
+++ b/dev-python/multidict/multidict-6.7.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="multidict implementation"
+HOMEPAGE="
+	https://github.com/aio-libs/multidict/
+	https://pypi.org/project/multidict/
+"
+SRC_URI="
+	https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+IUSE="+native-extensions"
+
+BDEPEND="
+	test? (
+		dev-python/objgraph[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't enable coverage or other pytest settings
+	sed -i -e '/cov/d' pytest.ini || die
+	# don't mangle CFLAGS
+	sed -i -e 's/^CFLAGS = .*/CFLAGS = []/' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! use native-extensions || [[ ${EPYTHON} == pypy3* ]]; then
+		local -x MULTIDICT_NO_EXTENSIONS=1
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/test_multidict_benchmarks.py
+		tests/test_views_benchmarks.py
+	)
+
+	rm -rf multidict || die
+
+	local cext=--c-extensions
+	if ! use native-extensions || [[ ${EPYTHON} == pypy3* ]]; then
+		cext=--no-c-extensions
+	fi
+	epytest "${cext}"
+}