Adding metadata

5 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/mpdlcd/Manifest b/dev-python/mpdlcd/Manifest
new file mode 100644
index 000000000000..0792edb63c23
--- /dev/null
+++ b/dev-python/mpdlcd/Manifest
@@ -0,0 +1 @@
+DIST mpdlcd-0.5.2.gh.tar.gz 30748 BLAKE2B 5609ac149a9aa806e516202adf1b9d0f4fc88e8370f331edc836082d7b3b85c519097149dd2b5cb838d8a9ff353421e17daf9236397e4b37e2923948f8dc9dac SHA512 e000120eee1ce99b549c5ac0cd00fba394ce1a373cce3dde819f6aabd6fc3b616e59ade6d6868b1e9f14afea4897cf541f2c3f5d0eaebcbbd03b15781a63b6fc
diff --git a/dev-python/mpdlcd/files/mpdlcd.confd b/dev-python/mpdlcd/files/mpdlcd.confd
new file mode 100644
index 000000000000..c7813cb0dea4
--- /dev/null
+++ b/dev-python/mpdlcd/files/mpdlcd.confd
@@ -0,0 +1,5 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Options for your started MPDlcd
+# MPDLCD_OPTS="--mpd=mpd.example.org:1234 --lcdproc=lcd.example.org:456 --syslog --syslog-facility=user2 --loglevel=debug --lcdd-debug"
diff --git a/dev-python/mpdlcd/files/mpdlcd.initd b/dev-python/mpdlcd/files/mpdlcd.initd
new file mode 100644
index 000000000000..c1e5bc7e1a3d
--- /dev/null
+++ b/dev-python/mpdlcd/files/mpdlcd.initd
@@ -0,0 +1,15 @@
+#!/sbin/openrc-run
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+name="MPDlcd"
+description="A small adapter which will display the status of a MPD server on a LCDproc screen"
+pidfile="/run/mpdlcd.pid"
+
+command="/usr/bin/mpdlcd"
+command_args="${MPDLCD_OPTS}"
+command_background="true"
+
+depend() {
+	need net
+}
diff --git a/dev-python/mpdlcd/metadata.xml b/dev-python/mpdlcd/metadata.xml
new file mode 100644
index 000000000000..a55c0b23db37
--- /dev/null
+++ b/dev-python/mpdlcd/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>conikost@gentoo.org</email>
+    <name>Conrad Kostecki</name>
+  </maintainer>
+  <longdescription>
+		MPDLcd is a small adapter which will display the status
+		of a MPD server on a LCD screen, through lcdproc.
+
+		It allows defining various layouts depending on LCD size,
+		with fix or moving parts.
+	</longdescription>
+  <upstream>
+    <bugs-to>https://github.com/rbarrois/mpdlcd/issues</bugs-to>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/mpdlcd/mpdlcd-0.5.2-r2.ebuild b/dev-python/mpdlcd/mpdlcd-0.5.2-r2.ebuild
new file mode 100644
index 000000000000..7a15f549edad
--- /dev/null
+++ b/dev-python/mpdlcd/mpdlcd-0.5.2-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A small tool to display the MPD status on a LCDproc server"
+HOMEPAGE="
+	https://github.com/rbarrois/mpdlcd/
+	https://pypi.org/project/mpdlcd/
+"
+SRC_URI="
+	https://github.com/rbarrois/mpdlcd/archive/refs/tags/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+RDEPEND="dev-python/python-mpd2"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Fix QA 'The license_file parameter is deprecated, use license_files instead.'
+	sed -e 's/license_file/license_files/g' -i setup.cfg || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman man/mpdlcd.1
+
+	insinto /etc
+	doins mpdlcd.conf
+
+	newinitd "${FILESDIR}"/mpdlcd.initd mpdlcd
+	newconfd "${FILESDIR}"/mpdlcd.confd mpdlcd
+}