Adding metadata

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/meson-python/Manifest b/dev-python/meson-python/Manifest
index a03fae6da0c5..93a0552c0b17 100644
--- a/dev-python/meson-python/Manifest
+++ b/dev-python/meson-python/Manifest
@@ -1 +1,2 @@
 DIST meson-python-0.20.0.gh.tar.gz 94677 BLAKE2B 9ab721d6c547f63a5235ac240f7eaa301ad1dda7d6cf077d11e06a5938ca58089f70396366fb9d0c73f94d190891eb46e0a20cde8aa2e4504b69784f1b4dfa25 SHA512 804f2885e2ebf8f2dfc2a91bf30a5306409684a8b6acdcb69217f45a5c6411e32b1373897efc71e148739502388727efc4e5d52b5f9375be676663ca3d189b6b
+DIST meson-python-0.21.0.gh.tar.gz 105284 BLAKE2B d0521471e3e46f4f921b889eaa4e76658bd98fb898e919717f61b4d97124a70bc53a0373972b7c363d16a0adabc8653cfb69a877571443ab6216ff0507de44c8 SHA512 16e43402b7102eabf6832755eeeb1483fbd9cff34de3e469dbb7d3c74e850800cfef79e71e049b19005397c74c90d4de1bf36f1291f6af9dfd84c7fde0bb493b
diff --git a/dev-python/meson-python/meson-python-0.21.0.ebuild b/dev-python/meson-python/meson-python-0.21.0.ebuild
new file mode 100644
index 000000000000..e16aee261d69
--- /dev/null
+++ b/dev-python/meson-python/meson-python-0.21.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Meson PEP 517 Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/meson-python/
+	https://github.com/mesonbuild/meson-python/
+"
+SRC_URI="
+	https://github.com/mesonbuild/meson-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-build/meson-0.63.0
+	!kernel_Darwin? ( dev-util/patchelf )
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		>=dev-python/cython-0.29.34
+		>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Strip unnecessary Python-level dependency on meson, it is used
+	# as an external executable anyway.
+	sed -i -e '/meson >=/d' pyproject.toml || die
+}
+
+src_test() {
+	# required by tests/test_sdist.py::test_reproducible
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "The Test Suite" || die
+	git init -q || die
+	git add -A || die
+	git commit -m init -q || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	unset NINJA
+
+	local EPYTEST_DESELECT=()
+	if ! has_version "dev-build/meson[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_wheel.py::test_vendored_meson
+		)
+	fi
+
+	epytest
+}