Adding metadata

3 files changed, 0 insertions, 106 deletions

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
deleted file mode 100644
index 62a46dff428b..000000000000
--- a/dev-python/kombu/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST kombu-5.6.2.tar.gz 472594 BLAKE2B 5764ddbbdc58926f399e18d08aa3eb31aee5bec03ebc7f493b74fc12a1a8c2ce84dbbbff323c9a61ecdfbd7407eda63cb97119030eda2d2d6ffb5bdffb9e0787 SHA512 9a6d51e2bdc6b6d993b68209bec8c4671305a40637e67b6a2f26db501bb8617cbca09670e80274d62f11144481f58b995f2fe7d1e71f5ce4c08c954fc164f33a
diff --git a/dev-python/kombu/kombu-5.6.2.ebuild b/dev-python/kombu/kombu-5.6.2.ebuild
deleted file mode 100644
index 5558bc8c959f..000000000000
--- a/dev-python/kombu/kombu-5.6.2.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1 optfeature pypi
-
-DESCRIPTION="AMQP Messaging Framework for Python"
-HOMEPAGE="
-	https://github.com/celery/kombu/
-	https://pypi.org/project/kombu/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="examples"
-
-RDEPEND="
-	>=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
-	<dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/tzdata-2025.2[${PYTHON_USEDEP}]
-	dev-python/vine[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
-		app-arch/brotli[python,${PYTHON_USEDEP}]
-		dev-python/hypothesis[${PYTHON_USEDEP}]
-		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
-		>=dev-python/pycurl-7.43.0.5[${PYTHON_USEDEP}]
-		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
-		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
-		dev-python/sqlalchemy[${PYTHON_USEDEP}]
-		dev-python/zstandard[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-freezer )
-distutils_enable_tests pytest
-distutils_enable_sphinx docs \
-	dev-python/sphinx-celery
-
-EPYTEST_DESELECT=(
-	# TODO
-	t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
-	t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
-	# bad filename assumption?
-	t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
-)
-EPYTEST_IGNORE=(
-	# obsolete Pyro4
-	t/unit/transport/test_pyro.py
-	# unpackaged azure
-	t/unit/transport/test_azurestoragequeues.py
-	# unpackage google-cloud
-	t/unit/transport/test_gcpubsub.py
-)
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# unpin deps (notably tzdata, sigh)
-	> requirements/default.txt || die
-}
-
-python_install_all() {
-	if use examples; then
-		docompress -x "/usr/share/doc/${PF}/examples"
-		docinto examples
-		dodoc -r examples/.
-	fi
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
-	optfeature "Etcd backend" dev-python/python-etcd
-	optfeature "MongoDB backend" dev-python/pymongo
-	optfeature "Redis backend" dev-python/redis
-	optfeature "sqlalchemy backend" dev-python/sqlalchemy
-	optfeature "yaml backend" dev-python/pyyaml
-	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
-	optfeature "brotli compression" "app-arch/brotli[python]"
-	optfeature "zstd compression" dev-python/zstandard
-}
diff --git a/dev-python/kombu/metadata.xml b/dev-python/kombu/metadata.xml
deleted file mode 100644
index 659be9f1d87e..000000000000
--- a/dev-python/kombu/metadata.xml
+++ /dev/null
@@ -1,13 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>python@gentoo.org</email>
-		<name>Python</name>
-	</maintainer>
-	<stabilize-allarches/>
-	<upstream>
-		<remote-id type="pypi">kombu</remote-id>
-		<remote-id type="github">celery/kombu</remote-id>
-	</upstream>
-</pkgmetadata>