Adding metadata

4 files changed, 151 insertions, 0 deletions

diff --git a/dev-python/jsonschema/Manifest b/dev-python/jsonschema/Manifest
new file mode 100644
index 000000000000..af0b06028642
--- /dev/null
+++ b/dev-python/jsonschema/Manifest
@@ -0,0 +1,3 @@
+DIST jsonschema-4.24.0.tar.gz 353480 BLAKE2B d063c9e55f25472b403645f9b274b8274cbaeca68f9cd1c88867431d05fca07a5885b805a7e91bd82f30cc6bc76dd44a2c561c0a69e5f1847dcea5a3ecbf90c2 SHA512 64840a1c989874fbdda2a996288ac0c5f46fe1ae9d5254eface832326b49d0090f33c3a06de952965b910eb8857daf9548e790de604abaf9cea588c8e3d89234
+DIST jsonschema-4.26.0.tar.gz 366583 BLAKE2B faa55e067a66c7a9778dfe40bc292c9fd99b4df815b68b2b1ceec088ce4b65ace65543273fde513b0cb34fc08813c546f31c030c35ff6cf6654996488a85909d SHA512 a7ae00392b8deb742f5826a65bce0a9149a67c6ddc4deff0bb2e99a79ed94f02c4738d93fef5247e30016fa38397ec68ecdead1c1d76a0caaf7755941544a0a2
+DIST jsonschema-4.26.0.tar.gz.provenance 9611 BLAKE2B 1d2e5b4e4044ab54aead8994d7b6ec1644e2d19facfec13a1d14f13e3f55533371ec93e4b83fdf3965b930251c93651515f4f052cd629d8e85b3fbc65f9f89b5 SHA512 f26f956159f0c31699af60dffa709eb0645ecd7cd27edfcc732143f3513a75c4ac28821bc360748479418ffc6771bac058bf3c70984ce87fb6dc870d6b77824e
diff --git a/dev-python/jsonschema/jsonschema-4.24.0.ebuild b/dev-python/jsonschema/jsonschema-4.24.0.ebuild
new file mode 100644
index 000000000000..cb92f08379ca
--- /dev/null
+++ b/dev-python/jsonschema/jsonschema-4.24.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="An implementation of JSON-Schema validation for Python"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema/
+	https://github.com/python-jsonschema/jsonschema/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-specifications-2023.03.6[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.4[${PYTHON_USEDEP}]
+	>=dev-python/rpds-py-0.7.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		!!dev-python/shiboken6
+	)
+"
+
+# formatter deps
+RDEPEND+="
+	dev-python/fqdn[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/isoduration[${PYTHON_USEDEP}]
+	>=dev-python/jsonpointer-1.13[${PYTHON_USEDEP}]
+	dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3986-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3987[${PYTHON_USEDEP}]
+	dev-python/uri-template[${PYTHON_USEDEP}]
+	>=dev-python/webcolors-24.6.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires pip, does not make much sense for the users
+	jsonschema/tests/test_cli.py::TestCLIIntegration::test_license
+	# fragile warning tests
+	jsonschema/tests/test_deprecations.py
+	# wtf?
+	jsonschema/tests/test_jsonschema_test_suite.py::test_suite_bug
+)
diff --git a/dev-python/jsonschema/jsonschema-4.26.0.ebuild b/dev-python/jsonschema/jsonschema-4.26.0.ebuild
new file mode 100644
index 000000000000..32b594caac14
--- /dev/null
+++ b/dev-python/jsonschema/jsonschema-4.26.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/python-jsonschema/jsonschema
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="An implementation of JSON-Schema validation for Python"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema/
+	https://github.com/python-jsonschema/jsonschema/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 x86"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-specifications-2023.03.6[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.4[${PYTHON_USEDEP}]
+	>=dev-python/rpds-py-0.25.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+		!!dev-python/shiboken6
+	)
+"
+
+# formatter deps
+RDEPEND+="
+	dev-python/fqdn[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/isoduration[${PYTHON_USEDEP}]
+	>=dev-python/jsonpointer-1.13[${PYTHON_USEDEP}]
+	dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3986-validator[${PYTHON_USEDEP}]
+	dev-python/rfc3987[${PYTHON_USEDEP}]
+	dev-python/uri-template[${PYTHON_USEDEP}]
+	>=dev-python/webcolors-24.6.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires pip, does not make much sense for the users
+		jsonschema/tests/test_cli.py::TestCLIIntegration::test_license
+		# fragile warning tests
+		jsonschema/tests/test_deprecations.py
+		# wtf?
+		jsonschema/tests/test_jsonschema_test_suite.py::test_suite_bug
+	)
+
+	case ${EPYTHON} in
+		python3.15*)
+			EPYTEST_DESELECT+=(
+				# pprint formatting changes
+				jsonschema/tests/test_exceptions.py::TestErrorInitReprStr::test_uses_pprint
+			)
+			;;
+	esac
+
+	epytest
+}
diff --git a/dev-python/jsonschema/metadata.xml b/dev-python/jsonschema/metadata.xml
new file mode 100644
index 000000000000..7a8ab6e0bb88
--- /dev/null
+++ b/dev-python/jsonschema/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chutzpah@gentoo.org</email>
+    <name>Patrick McLean</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+jsonschema is an implementation of JSON Schema (currently in Draft 3) for
+Python (supporting 2.6+ including Python 3).
+  </longdescription>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>