Adding metadatav21.1.5

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/js2py/js2py-0.70_p20210218.ebuild b/dev-python/js2py/js2py-0.70_p20210218.ebuild
new file mode 100644
index 000000000000..08f76b6703b3
--- /dev/null
+++ b/dev-python/js2py/js2py-0.70_p20210218.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_COMMIT="ea16b519a0f72e17416859a57890b8388fce6e39"
+
+MY_PN="Js2Py"
+MY_P="${MY_PN}-${PV}"
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="JavaScript to Python Translator & JavaScript interpreter in Python"
+HOMEPAGE="
+	http://piter.io/projects/js2py/
+	https://github.com/PiotrDabkowski/Js2Py/
+	https://pypi.org/project/Js2Py/
+"
+SRC_URI="https://github.com/PiotrDabkowski/${MY_PN}/archive/${MY_COMMIT}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pyjsparser-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/tzlocal-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${MY_COMMIT}"
+
+python_test() {
+	pushd ./tests >/dev/null || die
+
+	# Tests require "node_failed.txt" file where the logs are kept
+	if [[ -f ./node_failed.txt ]]; then
+		rm ./node_failed.txt || die
+	fi
+
+	touch ./node_failed.txt || die
+	"${EPYTHON}" ./run.py || die "tests failed with ${EPYTHON}"
+
+	popd >/dev/null || die
+}